主婦と.NETと犬のぶろぐ

ColorDialog（System.Windows.Forms.ColorDialog）

ColorDialog は、そのまんま Google 検索すると死ぬほど情報が出てきます。
なので、自分的に忘れそうな事をメモっておきました。
ColorDialog クラスは、CommonDialog クラスを継承しています。

■参考文献
ColorDialog クラス
CommonDialog クラス

■実行画像
フォームです。何のヘンテツもありません。


Button1 押下時の ColorDialog です。赤がデフォルトで選択されています。


Button2 押下時の ColorDialog です。プログラムで指定したカスタムカラーが[作成した色]に表示されています。


Button3 押下時の ColorDialog です。


Button4 押下時の ColorDialog です。ヘルプボタンを押下時にメッセージがでます。

Public Class ColorDialogTest
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        '' カラーピッカーのようなものを表示する。
        Me.ColorDialog1.FullOpen = True
        ' デフォルトの色を選択する
        Me.ColorDialog1.Color = System.Drawing.Color.Red
        ' ダイアログを開く
        Dim result As DialogResult = Me.ColorDialog1.ShowDialog()
        If result = Windows.Forms.DialogResult.OK Then
            Me.Label1.BackColor = Me.ColorDialog1.Color
            Me.Label1.Text = "R:" & Me.ColorDialog1.Color.R.ToString() & _
                             " G:" & Me.ColorDialog1.Color.G.ToString() & _
                             " B:" & Me.ColorDialog1.Color.B.ToString()
        End If
    End Sub


    Private Sub Button2_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button2.Click
        '' これ以降、プログラム内で ColorDialog を作成する。
        Using myColorDialog As ColorDialog = New ColorDialog
            ' CustomColor を設定
            myColorDialog.CustomColors = New Integer() {&H6699, &HFF9933}
            Dim result As DialogResult = myColorDialog.ShowDialog()
            If result = Windows.Forms.DialogResult.OK Then
                Me.Label2.BackColor = myColorDialog.Color
            End If
        End Using
    End Sub


    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        '' 純色のみ表示する
        Using myColorDialog As ColorDialog = New ColorDialog
            myColorDialog.SolidColorOnly = True
            Dim result As DialogResult = myColorDialog.ShowDialog()
            If result = Windows.Forms.DialogResult.OK Then
                Me.Label3.BackColor = myColorDialog.Color
            End If
        End Using
    End Sub


    Private Sub Button4_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles Button4.Click
        '' AnyColor
        Using myColorDialog As ColorDialog = New ColorDialog
            myColorDialog.AllowFullOpen = False
            myColorDialog.AnyColor = True
            myColorDialog.SolidColorOnly = False
            myColorDialog.ShowHelp = True
            ' ヘルプボタンが押されたときのイベントを登録する
            AddHandler myColorDialog.HelpRequest, _
            New EventHandler(AddressOf Me.ColorDialogHelpRequested)
            Dim result As DialogResult = myColorDialog.ShowDialog()
            If result = Windows.Forms.DialogResult.OK Then
                Me.Label4.BackColor = myColorDialog.Color
            End If
        End Using
    End Sub


    Private Sub ColorDialogHelpRequested(ByVal sender As Object, ByVal e As System.EventArgs)
        ' sender は ColorDialog オブジェクトになります。
        MessageBox.Show("好きな色を選んでください")
    End Sub
End Class

投稿日時 : 2006年12月13日 10:43