.NET Component のお勉強（自分用めも）

TreeView（System.Windows.Forms.TreeView）

Wed, 23 May 2007 14:14:00 GMT

TreeView が大好きなお客さん多いですね。
Windows のアプリケーションの UI に近いものを表現できるゆえ、
直観的な操作が可能だから、ってとこですかね。

しかしながら TreeView に Node を追加していく作業って
メタ的なっていうか再帰的な考えができないとなかなか難しいとこでして
Windows 駆け出しプログラマの人が結構つまづいてるんじゃないかなぁと思ったり。

かく言うワタシも久々に TreeView と格闘したので
ヘンなところで悩んじゃったなぁ。
その割にはいつもながらに出来の悪いプログラムですみませぬ。。。

ちなみに DataBase の取得元のテーブルはこんな感じです。

■参考文献
TreeView クラス
 TreeView コントロール (Windows フォーム)

■実行画像
http://blogs.wankuma.com/opml.aspx から取得したものを TreeView に描画

Public Class TreeViewTest


    Private Sub TreeViewTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Dim tabCtrl As TabControl = New TabControl()
        Me.Controls.Add(tabCtrl)
        tabCtrl.Dock = DockStyle.Fill


        '' データベースから
        Dim dbTabpage As TabPage = New TabPage("DB")
        tabCtrl.TabPages.Add(dbTabpage)
        Dim dbTreeView As TreeView = New TreeView()
        dbTabpage.Controls.Add(dbTreeView)
        With dbTreeView
            .Dock = DockStyle.Fill
            ' TreeView の幅全体を選択したように表示するか否か
            .FullRowSelect = True
            ' Focus を失っても強調表示したままにするか否か
            .HideSelection = True
            ' ハイパーリンク表示するか否か
            .HotTracking = True
            .Indent = 25
            .ItemHeight = 25
            ' ラベル編集を可能にするか否か
            .LabelEdit = True
            ' ノード間の線を表示するか否か
            .ShowLines = False


            AddHandler .AfterSelect, AddressOf DBtree_AfterSelect
            .BeginUpdate()
            ' 描画
            Me.CreateTreeFromDataBase(dbTreeView)
            .EndUpdate()
        End With


        '' ファイルシステムから
        Dim fileTabpage As TabPage = New TabPage("File")
        tabCtrl.TabPages.Add(fileTabpage)
        Dim fileTreeView As TreeView = New TreeView()
        fileTabpage.Controls.Add(fileTreeView)
        With fileTreeView
            .Dock = DockStyle.Fill
            .CheckBoxes = True
            AddHandler .AfterSelect, AddressOf Filetree_AfterSelect
        End With
        ' 描画
        fileTreeView.BeginUpdate()
        Me.CreateTreeFromFileSystem(fileTreeView, "C:\Windows")
        fileTreeView.EndUpdate()


        '' XML ファイルから
        Dim xmlTabpage As TabPage = New TabPage("XML")
        tabCtrl.TabPages.Add(xmlTabpage)
        Dim xmlTreeView As TreeView = New TreeView()
        xmlTabpage.Controls.Add(xmlTreeView)
        Dim imgLst As ImageList = New ImageList()
        imgLst.Images.AddRange(New Image() {My.Resources.wankuma, My.Resources.blackwankuma})
        With xmlTreeView
            .ImageList = imgLst
            .Dock = DockStyle.Fill
            AddHandler .AfterSelect, AddressOf Xmltree_AfterSelect
        End With
        ' 描画
        fileTreeView.BeginUpdate()
        Me.CrerateTreeFromOpml(xmlTreeView)
        fileTreeView.EndUpdate()


    End Sub


    Private Sub DBtree_AfterSelect(ByVal sender As Object, ByVal e As TreeViewEventArgs)
        Console.WriteLine("Action:" & e.Action.ToString())
        Console.WriteLine("Node:" & e.Node.Text)
    End Sub


    Private Sub Filetree_AfterSelect(ByVal sender As Object, ByVal e As TreeViewEventArgs)
        Dim fileNode As FileSystemNode = DirectCast(e.Node, FileSystemNode)
        Console.WriteLine("Attributes:" & fileNode.Info.Attributes.ToString())
        Console.WriteLine("CreationTime:" & fileNode.Info.CreationTime.ToString("yyyy/MM/dd HH:mm;ss"))
        Console.WriteLine("LastAccessTime:" & fileNode.Info.LastAccessTime.ToString("yyyy/MM/dd HH:mm;ss"))
        Console.WriteLine("LastWriteTime:" & fileNode.Info.LastWriteTime.ToString("yyyy/MM/dd HH:mm;ss"))
    End Sub


    Private Sub Xmltree_AfterSelect(ByVal sender As Object, ByVal e As TreeViewEventArgs)
        Dim node As OpmlNode = DirectCast(e.Node, OpmlNode)
        Console.WriteLine("Name:" & node.Text)
        Console.WriteLine("Url:" & node.Url)
        Console.WriteLine("Rss:" & node.Rss)
    End Sub


    '' Database
    Private Sub CreateTreeFromDataBase(ByVal tree As TreeView)
        Const CONNECTION_STRING As String = _
        "Data Source=(local);Initial Catalog=Test;Integrated Security=SSPI;"
        Const SQL As String = _
        "SELECT    dbo.Table1.ID AS ParentID, " & _
        "          dbo.Table1.NAME AS ParentName, " & _
        "          SubTable.ID AS ChildID, " & _
        "          SubTable.NAME AS ChildName " & _
        "FROM      dbo.Table1 SubTable LEFT OUTER JOIN " & _
        "          dbo.Table1 ON SubTable.PARENT_ID = dbo.Table1.ID " & _
        "ORDER BY  dbo.Table1.ID, SubTable.ID; "


        ' DataBase から値の取得
        Dim treeDt As DataTable = New DataTable()
        Using con As SqlClient.SqlConnection = _
        New SqlClient.SqlConnection(CONNECTION_STRING)
            con.Open()
            Try
                Using adapter As SqlClient.SqlDataAdapter = _
                New SqlClient.SqlDataAdapter(SQL, con)


                    adapter.Fill(treeDt)
                End Using
            Finally
                If Not con Is Nothing Then con.Close()
            End Try
        End Using


        ' TreeView に描画
        For Each row As DataRow In treeDt.Rows
            Dim node As TreeNode = New TreeNode()
            node.Tag = Convert.ToInt32(row("ChildID"))
            node.Text = Convert.ToString(row("ChildName"))


            If TypeOf (row("ParentID")) Is DBNull Then
                ' root の時
                tree.Nodes.Add(node)
            Else
                ' root 以外の時
                Me.m_FoundNode = Nothing
                Me.FindTreeNode(Convert.ToInt32(row("ParentID")), tree.Nodes)
                Dim parent As TreeNode = Me.m_FoundNode
                parent.Nodes.Add(node)
            End If
        Next
    End Sub
    Private m_FoundNode As TreeNode
    Private Sub FindTreeNode(ByVal tagData As Integer, ByVal nodes As TreeNodeCollection)
        For Each node As TreeNode In nodes
            If Convert.ToInt32(node.Tag) = tagData Then
                Me.m_FoundNode = node
            ElseIf node.Nodes.Count > 0 Then
                Me.FindTreeNode(tagData, node.Nodes)
            End If
        Next
    End Sub


    '' FileSystem
    Private Sub CreateTreeFromFileSystem(ByVal tree As TreeView, ByVal rootPath As String)


        Dim rootNode As FileSystemNode = New FileSystemNode(New System.IO.DirectoryInfo(rootPath))
        tree.Nodes.Add(rootNode)


        Dim rootFiles As String() = System.IO.Directory.GetFiles(rootPath)
        Dim directries As String() = System.IO.Directory.GetDirectories(rootPath)


        For Each rootDirectory As String In directries
            Dim dirNode As FileSystemNode = New FileSystemNode(New System.IO.DirectoryInfo(rootDirectory))
            rootNode.Nodes.Add(dirNode)
            Dim dirFiles As String() = System.IO.Directory.GetFiles(rootDirectory)
            For Each subfile As String In dirFiles
                dirNode.Nodes.Add(New FileSystemNode(New System.IO.FileInfo(subfile)))
            Next
        Next


        For Each rootFile As String In rootFiles
            rootNode.Nodes.Add(New FileSystemNode(New System.IO.FileInfo(rootFile)))
        Next
    End Sub


    '' Xml
    Private Sub CrerateTreeFromOpml(ByVal tree As TreeView)
        Dim rootNode As OpmlNode = _
        New OpmlNode("わんくま", "http://blogs.wankuma.com/", "http://blogs.wankuma.com/MainFeed.aspx")
        rootNode.ImageIndex = 0
        tree.Nodes.Add(rootNode)


        Using reader As Xml.XmlTextReader = New Xml.XmlTextReader("D:\opml.xml")
            While reader.Read
                If reader.Name = "outline" Then
                    Dim node As OpmlNode = _
                    New OpmlNode(reader.GetAttribute("title"), _
                                 reader.GetAttribute("htmlUrl"), _
                                 reader.GetAttribute("xmlUrl"))
                    node.ImageIndex = 1
                    rootNode.Nodes.Add(node)
                End If
            End While
        End Using
    End Sub
End Class


'' FileSystemInfo を持てるように拡張した TreeNode
Public Class FileSystemNode
    Inherits TreeNode


    Private m_info As System.IO.FileSystemInfo


    Public Sub New(ByVal info As System.IO.FileSystemInfo)
        MyBase.Text = info.Name
        Me.m_info = info
    End Sub


    Public ReadOnly Property Info() As System.IO.FileSystemInfo
        Get
            Return Me.m_info
        End Get
    End Property
End Class


'' わんくま OPML 用
Public Class OpmlNode
    Inherits TreeNode


    Private m_url As String
    Private m_rss As String


    Public ReadOnly Property Url() As String
        Get
            Return Me.m_url
        End Get
    End Property


    Public ReadOnly Property Rss() As String
        Get
            Return Me.m_rss
        End Get
    End Property


    Public Sub New(ByVal name As String, ByVal url As String, ByVal rss As String)
        MyBase.Text = name
        Me.m_url = url
        Me.m_rss = rss
    End Sub
End Class

TrackBar（System.Windows.Forms.TrackBar）

Tue, 15 May 2007 11:36:00 GMT

TrackBar って業務アプリケーションでどういうときに使うんだろう。。。
全く思い浮かびませんでした。
無理やり考えてみると、画面の文字サイズを変えるプロパティ画面みたいなところとか？

■参考文献
TrackBar クラス
 TrackBar コントロール (Windows フォーム)

■実行画像
R・G・B の各つまみを動かすと Form の背景色が変わります～（なんという貧弱な発想のプログラム。。。orz）

Public Class TrackBarTest


    Private m_rTrackBar As TrackBar 'R
    Private m_gTrackBar As TrackBar 'G
    Private m_bTrackBar As TrackBar 'B
    Private m_statusStrip As StatusStrip


    Private Sub TrackBarTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        '' 赤
        Me.m_rTrackBar = New TrackBar()
        Me.Controls.Add(Me.m_rTrackBar)
        With Me.m_rTrackBar
            .BeginInit()
            .Dock = DockStyle.Bottom
            .BackColor = Color.Red
            ' 最小・最大
            .Minimum = 0
            .Maximum = 255
            ' TrackBar の向き
            .Orientation = Orientation.Horizontal ' 既定値
            ' 方向キーやマウスでの移動させた時の増減する値
            .SmallChange = 1 ' 既定値
            ' PageUp/PageDown または 側の TrackBar をクリックしたときに増減する値
            .LargeChange = 10 ' 既定値 5
            ' 目盛り間のデルタ
            .TickFrequency = 1 ' 既定値
            .TickStyle = TickStyle.BottomRight ' 既定値
            .Value = Me.BackColor.R
            .EndInit()
            AddHandler .Scroll, AddressOf TrackBar_Scroll
        End With


        '' 緑
        Me.m_gTrackBar = New TrackBar()
        Me.Controls.Add(Me.m_gTrackBar)
        With Me.m_gTrackBar
            .BeginInit()
            .Dock = DockStyle.Bottom
            .BackColor = Color.Green
            .Minimum = 0
            .Maximum = 255
            .Orientation = Orientation.Horizontal ' 既定値
            .SmallChange = 1 ' 既定値
            .LargeChange = 10 ' 既定値 5
            .TickFrequency = 1 ' 既定値
            .TickStyle = TickStyle.TopLeft ' 既定値 BottomRight
            .Value = Me.BackColor.G
            .EndInit()
            AddHandler .Scroll, AddressOf TrackBar_Scroll
        End With


        '' 青
        Me.m_bTrackBar = New TrackBar()
        Me.Controls.Add(Me.m_bTrackBar)
        With Me.m_bTrackBar
            .BeginInit()
            .Dock = DockStyle.Bottom
            .BackColor = Color.Blue
            .Minimum = 0
            .Maximum = 255
            .Orientation = Orientation.Horizontal ' 既定値
            .SmallChange = 1 ' 既定値
            .LargeChange = 10 ' 既定値 5
            .TickFrequency = 1 ' 既定値
            .TickStyle = TickStyle.Both ' 既定値 BottomRight
            .Value = Me.BackColor.B
            .EndInit()
            AddHandler .Scroll, AddressOf TrackBar_Scroll
        End With


        Me.m_statusStrip = New StatusStrip()
        Me.Controls.Add(Me.m_statusStrip)
        With Me.m_statusStrip
            .Dock = DockStyle.Bottom
            .Items.Add(New ToolStripLabel())
        End With
    End Sub


    Private Sub TrackBar_Scroll(ByVal sender As Object, ByVal e As EventArgs)
        Me.BackColor = System.Drawing.Color.FromArgb(Me.m_rTrackBar.Value, _
                                                     Me.m_gTrackBar.Value, _
                                                     Me.m_bTrackBar.Value)
        Me.m_statusStrip.Items(0).Text = "R:" & Me.m_rTrackBar.Value.ToString() & _
                                         " G:" & Me.m_gTrackBar.Value.ToString() & _
                                         " B:" & Me.m_bTrackBar.Value.ToString()
    End Sub
End Class

ToolTip（System.Windows.Forms.ToolTip）

Mon, 14 May 2007 11:35:00 GMT

使っているようで実はあまり使っていない ToolTip です。 .NET Framework1.1 の時、要望があれば適宜使っていたような。
IsBaloon でかっちょいい吹き出し型のやつが簡単に実装できる様になっているのはいいですねぇ。

入力ガイド等を表示してアクセシビリティを UP、ですかね。

■参考文献
ToolTip クラス
 ToolTip コンポーネント (Windows フォーム)

■実行画像
今回はすべてデザイナで配置。

Public Class ToolTipTest


    Private Sub ToolTipTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        With Me.ToolTip1
            .Active = True ' 既定値
            .AutomaticDelay = 1000 ' 既定値 500 ミリ秒
            ' ポインタが静止している時のツールヒントの表示時間
            .AutoPopDelay = 20000 ' 既定値 AutomaticDelay × 10
            ' ツール ヒントが表示されるまでに経過する時間
            .InitialDelay = 100 ' 既定値 AutomaticDelay
            ' コントロールを移動した先でツールヒント ウィンドウが表示されるまでに経過する必要のある時間
            .ReshowDelay = 100 ' 既定値 AutomaticDelay / 5


            .BackColor = Color.LightYellow
            .ForeColor = Color.Salmon


            ' Baloon 表示にする
            .IsBalloon = True
            ' 対象のコントロールが非アクティブな状態でも表示するか
            .ShowAlways = False ' 既定値
            ' 「&」を除外するか否か
            .StripAmpersands = False ' 既定値
            ' 表示するアイコンの種類
            .ToolTipIcon = ToolTipIcon.Info ' 既定値 ToolTipIcon.None
            .ToolTipTitle = "これはタイトルです"
            ' アニメーション効果を利用するか否か
            .UseAnimation = True ' 既定値
            ' フェード効果を利用するか否か
            .UseFading = True ' 既定値


            ' ToolTip を設定
            .SetToolTip(Me.TextBox1, "これは&てきすとぼっくす")
            .SetToolTip(Me.ComboBox1, "これは&こんぼぼっくす")
        End With
    End Sub


    Private Sub ToolTip1_Popup(ByVal sender As Object, ByVal e As System.Windows.Forms.PopupEventArgs) Handles ToolTip1.Popup
        Console.WriteLine(StrDup(10, "="c))
        Console.WriteLine("Popup")
        Console.WriteLine(StrDup(10, "="c))
        Console.WriteLine("AssociatedControl:" & e.AssociatedControl.Name)
        Console.WriteLine("AssociatedWindow:" & e.AssociatedWindow.Handle.ToInt32.ToString())
        Console.WriteLine("IsBalloon:" & e.IsBalloon.ToString())
        Console.WriteLine("ToolTipSize(w,h):(" & e.ToolTipSize.Width.ToString() & "," & e.ToolTipSize.Height.ToString() & ")")


        Dim text As String = Me.ToolTip1.GetToolTip(e.AssociatedControl)
        Console.WriteLine("text:" & text)
    End Sub
End Class

ToolStripConainer（System.Windows.Forms.ToolStripConainer）

Fri, 11 May 2007 12:03:00 GMT

上下左右のパネルは ToolStripPanel オブジェクトで
真ん中のは ToolStripContentPanel オブジェクトらしいです。
MenuStrip と StatusStrip と ToolStrip が配置できますよー。
そのくらい。

UI のデザインの種類が多くなったかな、位にしか個人的にはとらえておりませぬ。

■参考文献
ToolStripContainer クラス
 ToolStripContainer コントロール (Windows フォーム)

■実行画像
今回は全部コードで配置しました。

Public Class ToolStripContainerTest


    Private m_container As ToolStripContainer


    Private Sub ToolStripContainerTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Me.m_container = New ToolStripContainer()
        Me.Controls.Add(Me.m_container)


        ' 上用
        Dim mnuStrip As MenuStrip = New MenuStrip()
        Dim mnuStripMenu As ToolStripButton = New ToolStripButton("This is MenuStrip")
        mnuStrip.Items.Add(mnuStripMenu)
        AddHandler mnuStripMenu.Click, AddressOf menuOnClick


        ' 左用
        Dim toolstripLeft As ToolStrip = New ToolStrip()
        Dim toolstripLeftMenu As ToolStripButton = New ToolStripButton("This is ToolStrip(L)")
        toolstripLeft.Items.Add(toolstripLeftMenu)
        AddHandler toolstripLeftMenu.Click, AddressOf menuOnClick


        ' 右用
        Dim toolstripRight As ToolStrip = New ToolStrip()
        Dim toolstripRightMenu As ToolStripButton = New ToolStripButton("This is ToolStrip(R)")
        toolstripRight.Items.Add(toolstripRightMenu)
        AddHandler toolstripRightMenu.Click, AddressOf menuOnClick


        ' 下用
        Dim ststrip As StatusStrip = New StatusStrip()
        Dim ststripMenu As ToolStripButton = New ToolStripButton("This is StatusStrip", My.Resources.wankuma)
        ststrip.Items.Add(ststripMenu)
        AddHandler ststripMenu.Click, AddressOf menuOnClick


        ' 真ん中用
        Dim pic As PictureBox = New PictureBox()
        With pic
            .Image = My.Resources.中さん
            .SizeMode = PictureBoxSizeMode.Zoom
            .Dock = DockStyle.Fill
            AddHandler .DoubleClick, AddressOf pictureBox_DoubleClick
        End With


        With Me.m_container
            .Dock = DockStyle.Fill
            ' 各 Strip の配置 と 左右の背景色の変更
            .TopToolStripPanel.Controls.Add(mnuStrip)
            .LeftToolStripPanel.Controls.Add(toolstripLeft)
            .LeftToolStripPanel.BackColor = Color.LightSalmon
            .RightToolStripPanel.Controls.Add(toolstripRight)
            .RightToolStripPanel.BackColor = Color.LightBlue
            .BottomToolStripPanel.Controls.Add(ststrip)


            ' 真ん中に PictureBox の配置
            .ContentPanel.Controls.Add(pic)
        End With
    End Sub


    Private Sub pictureBox_DoubleClick(ByVal sender As Object, ByVal e As System.EventArgs)
        With Me.m_container
            .TopToolStripPanelVisible = True
            .LeftToolStripPanelVisible = True
            .RightToolStripPanelVisible = True
            .BottomToolStripPanelVisible = True
        End With
    End Sub


    Private Sub menuOnClick(ByVal sender As Object, ByVal e As EventArgs)
        Dim tstripButton As ToolStripButton = DirectCast(sender, ToolStripButton)
        Dim pnl As ToolStripPanel = DirectCast(tstripButton.Owner.Parent, ToolStripPanel)


        pnl.Visible = False


        '' 以下でも同じ
        'Select Case pnl.Dock
        '    Case DockStyle.Top
        '        Me.m_container.TopToolStripPanelVisible = False
        '    Case DockStyle.Left
        '        Me.m_container.LeftToolStripPanelVisible = False
        '    Case DockStyle.Right
        '        Me.m_container.RightToolStripPanelVisible = False
        '    Case DockStyle.Bottom
        '        Me.m_container.BottomToolStripPanelVisible = False
        'End Select
    End Sub
End Class

ToolStrip（System.Windows.Forms.ToolStrip）

Wed, 09 May 2007 12:55:00 GMT

ToolStrip 何とかってこの一連の勉強で一杯触りましたよね。
てか、もうおなかいっぱい。。。

しかし、ちゃんとドキュメントをしらみつぶしに読んでくと
結構いろいろあって、しばらくぶりの更新なのに疲れてしまいました。
なので、今回もテキトーなプログラムを書いてみました。

■参考文献
ToolStrip クラス
 ToolStrip コントロール (Windows フォーム)
ToolStrip コントロールのアーキテクチャ

■実行画像
ToolStrip だけデザイナ上で配置してあります。

Public Class ToolStripTest


    Private Sub ToolStripTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        ' Button の配置
        Dim btn As ToolStripButton = New ToolStripButton()
        Me.ToolStrip1.Items.Add(btn)
        With btn
            .Text = "AllowItemReorder"
            .CheckOnClick = True ' トグルボタンの外観にする
            AddHandler .Click, AddressOf Button_Click
        End With


        ' ComboBox の配置
        Dim dockCmb As ToolStripComboBox = New ToolStripComboBox()
        Me.ToolStrip1.Items.Add(dockCmb)
        With dockCmb
            ' AutoComplete を有効にしてみる
            .AutoCompleteMode = AutoCompleteMode.SuggestAppend
            .AutoCompleteSource = AutoCompleteSource.ListItems
            .Items.AddRange(New Object() { _
                            DockStyle.Bottom, _
                            DockStyle.Fill, _
                            DockStyle.Left, _
                            DockStyle.None, _
                            DockStyle.Right, _
                            DockStyle.Top})
            .Overflow = ToolStripItemOverflow.Never
            AddHandler .SelectedIndexChanged, AddressOf DockComboBox_SelectedIndexChanged
        End With


        ' もいっこ ComboBox
        Dim layoutStyleCmb As ToolStripComboBox = New ToolStripComboBox()
        Me.ToolStrip1.Items.Add(layoutStyleCmb)
        With layoutStyleCmb
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.AddRange(New Object() { _
                            ToolStripLayoutStyle.Flow, _
                            ToolStripLayoutStyle.HorizontalStackWithOverflow, _
                            ToolStripLayoutStyle.StackWithOverflow, _
                            ToolStripLayoutStyle.Table, _
                            ToolStripLayoutStyle.VerticalStackWithOverflow})
            AddHandler .SelectedIndexChanged, AddressOf LayoutStyleComboBox_SelectedIndexChanged
        End With


        ' ToolStripSplitButton・ToolStripLabel の配置
        Dim splitButton As ToolStripSplitButton = New ToolStripSplitButton()
        Me.ToolStrip1.Items.Add(splitButton)


        Dim rendermodeCustomLabel As ToolStripLabel = New ToolStripLabel()
        With rendermodeCustomLabel
            .Text = ToolStripRenderMode.Custom.ToString()
            .Tag = ToolStripRenderMode.Custom
        End With
        Dim rendermodeManagerRenderModeLabel As ToolStripLabel = New ToolStripLabel()
        With rendermodeManagerRenderModeLabel
            .Text = ToolStripRenderMode.ManagerRenderMode.ToString()
            .Tag = ToolStripRenderMode.ManagerRenderMode
        End With
        Dim rendermodeProfessionalLabel As ToolStripLabel = New ToolStripLabel()
        With rendermodeProfessionalLabel
            .Text = ToolStripRenderMode.Professional.ToString()
            .Tag = ToolStripRenderMode.Professional
        End With
        Dim rendermodeSystemLabel As ToolStripLabel = New ToolStripLabel()
        With rendermodeSystemLabel
            .Text = ToolStripRenderMode.System.ToString()
            .Tag = ToolStripRenderMode.System
        End With
        With splitButton
            .Text = "RenderMode"
            .DropDownItems.AddRange(New ToolStripLabel() { _
                                   rendermodeCustomLabel, _
                                   rendermodeManagerRenderModeLabel, _
                                   rendermodeProfessionalLabel, _
                                   rendermodeSystemLabel})
            AddHandler .ButtonClick, AddressOf SplitButton_ButtonClick
            AddHandler .DropDownItemClicked, AddressOf SplitButton_DropDownItemClicked
        End With


        ' ToolStripSeparator の配置
        Dim separator As ToolStripSeparator = New ToolStripSeparator()
        Me.ToolStrip1.Items.Add(separator)


        ' ToolStripDropDownButton の配置
        Dim dropDownButton As ToolStripDropDownButton = New ToolStripDropDownButton()
        Me.ToolStrip1.Items.Add(dropDownButton)
        With dropDownButton
            .Text = "ToolStripDropDownButton"
            .DropDownItems.AddRange(New ToolStripItem() { _
                                    New ToolStripTextBox(), _
                                    New ToolStripMenuItem("MenuItem"), _
                                    New ToolStripStatusLabel("StatusLabel"), _
                                    New ToolStripProgressBar()})
        End With


        With Me.ToolStrip1
            .Dock = DockStyle.Left
            ' Margin を自分で設定する
            .AutoSize = False
            .Margin = New Padding(2, 0, 2, 0)
            ' Tab での移動を可能にする
            .TabStop = True
            .AllowMerge = True
        End With
        Me.Size = New Size(400, Me.Height)


    End Sub


    Private Sub Button_Click(ByVal sender As Object, ByVal e As EventArgs)
        Dim btn As ToolStripButton = DirectCast(sender, ToolStripButton)
        Me.ToolStrip1.AllowItemReorder = btn.Checked
    End Sub


    Private Sub DockComboBox_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim dockCmb As ToolStripComboBox = DirectCast(sender, ToolStripComboBox)
        Me.ToolStrip1.Dock = DirectCast(dockCmb.SelectedItem, DockStyle)
    End Sub


    Private Sub LayoutStyleComboBox_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim layoutStyleCmb As ToolStripComboBox = DirectCast(sender, ToolStripComboBox)
        Me.ToolStrip1.LayoutStyle = DirectCast(layoutStyleCmb.SelectedItem, ToolStripLayoutStyle)
    End Sub


    Private Sub SplitButton_ButtonClick(ByVal sender As Object, ByVal e As EventArgs)
        MessageBox.Show("SplitButton がクリックされました")
    End Sub


    Private Sub SplitButton_DropDownItemClicked(ByVal sender As Object, ByVal e As ToolStripItemClickedEventArgs)
        Dim clickedItem As ToolStripItem = e.ClickedItem
        Dim rendermode As ToolStripRenderMode = DirectCast(clickedItem.Tag, ToolStripRenderMode)
        If rendermode = ToolStripRenderMode.Custom Then
            Me.ToolStrip1.Renderer = New MyCustomRenderer()
        Else
            Me.ToolStrip1.Renderer = Nothing
            Me.ToolStrip1.RenderMode = rendermode
        End If
    End Sub
End Class


''' <summary>
''' カスタム描画クラス
''' </summary>
Public Class MyCustomRenderer
    Inherits ToolStripRenderer


    Protected Overrides Sub OnRenderToolStripBackground(ByVal e As System.Windows.Forms.ToolStripRenderEventArgs)
        MyBase.OnRenderToolStripBackground(e)
        Using brush As System.Drawing.Drawing2D.LinearGradientBrush _
                       = New System.Drawing.Drawing2D.LinearGradientBrush(e.ToolStrip.ClientRectangle, Color.White, Color.SkyBlue, 0.0F)
            e.Graphics.FillRectangle(brush, e.AffectedBounds)
        End Using
    End Sub
End Class

Timer（System.Windows.Forms.Timer）

Fri, 27 Apr 2007 11:05:00 GMT

Timer かぁ。。。 VB6 の時に時計表示機能位しか業務で使ったことないなぁ。

VB6 の時の Timer と、.NET Framework 上における System.Windows.Forms.Timer の違いは
Timer コントロール (Visual Basic 6.0 ユーザー向け) にまとめられています。

タイマーの制限事項については、以下にあります。
Windows フォームの Timer コンポーネントの Interval プロパティの制限
Interval に設定できる値は 1 分強 (約 64.8 秒)が MAX なんですねぇ。
そんなにでかい値をセットしようとしたことがないから知らんかったー。

■参考文献
Timer クラス
 Timer コンポーネント (Windows フォーム)

■実行画像
わっ。こういうの、もうさんざん見あきてますね。

Public Class TimerTest


    Private m_timeLabel As Label = New Label()


    Private Sub TimerTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Me.Controls.Add(Me.m_timeLabel)
        With Me.m_timeLabel
            .Location = New Point(10, 10)
            .AutoSize = True
            .Font = New Font(.Font.FontFamily, 18.0F, FontStyle.Regular)
            .BorderStyle = BorderStyle.Fixed3D
        End With


        Dim startButton As Button = New Button
        Me.Controls.Add(startButton)
        With startButton
            .Location = New Point(10, 100)
            .Text = "Start"
            .AutoSize = True
            AddHandler .Click, AddressOf StartButton_Click
        End With


        Dim stopButton As Button = New Button
        Me.Controls.Add(stopButton)
        With stopButton
            .Location = New Point(100, 100)
            .Text = "Stop"
            .AutoSize = True
            AddHandler .Click, AddressOf StopButton_Click
        End With


        With Me.Timer1
            .Interval = 1000 ' 1 秒ごとに Tick イベントを発生させる
        End With
    End Sub


    Private Sub Timer1_Tick(ByVal sender As Object, ByVal e As System.EventArgs) Handles Timer1.Tick
        Me.DisplayTime("Tick")
    End Sub


    Private Sub StartButton_Click(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.Timer1.Start()
        Me.DisplayTime("Start")
    End Sub


    Private Sub StopButton_Click(ByVal sender As Object, ByVal e As System.EventArgs)
        Me.Timer1.Stop()
        Me.DisplayTime("Stop")
    End Sub


    Private Sub DisplayTime(ByVal eventName As String)
        Me.m_timeLabel.Text = DateTime.Now.ToString("yyyy/MM/dd HH:mm:ss") & _
                      ControlChars.NewLine & _
                      "Enabled:" & Me.Timer1.Enabled.ToString() & _
                      ControlChars.NewLine & _
                      "Event:" & eventName
    End Sub
End Class

TextBox（System.Windows.Forms.TextBox）

Thu, 26 Apr 2007 12:13:00 GMT

うーん。
何も書くようなことがないなぁ。。。
とりあえず、プロパティを動的に変更してみるサンプルを作成してみました。

「ユーザーに入力できませんよ」という意志を伝えるとき、
Enabled = False にする方と、ReadOnly = True にする場合とがあるのですが
ワタシは ReadOnly = True 派かなぁ。
特に理由はなくて、単純な好みで言ってますが。

■参考文献
TextBox クラス
 TextBox コントロール (Windows フォーム)

■実行画像
こんな感じで設定できます。カーソルを最後に持っていくか否かについてはちょっと周りとは違いますが。

Public Class TextBoxTest


    Private m_textBox As TextBox = New TextBox()
    Private m_moveCursor As Boolean = False


    Private Sub TextBoxTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Dim tabCtrl As TabControl = New TabControl()
        Me.Controls.Add(tabCtrl)
        tabCtrl.Dock = DockStyle.Fill
        tabCtrl.TabPages.Clear()


        Dim textBoxSettingTabPage As TabPage = New TabPage("設定")
        tabCtrl.TabPages.Add(textBoxSettingTabPage)


        Dim textBoxTabPage As TabPage = New TabPage("TextBox")
        tabCtrl.TabPages.Add(textBoxTabPage)
        textBoxTabPage.Controls.Add(Me.m_textBox)


        Me.m_textBox.Dock = DockStyle.Top
        Me.m_textBox.Text = "ふじことエデンは楽しい友達"
        AddHandler Me.m_textBox.Enter, AddressOf TextBox_Enter
        AddHandler Me.m_textBox.Leave, AddressOf TextBox_Leave


        ' Enter 入力を受け付けるか否か
        Dim acceptsReturnChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(acceptsReturnChkBox)
        With acceptsReturnChkBox
            .Location = New Point(10, 10)
            .Text = "AcceptsReturn"
            .Checked = Me.m_textBox.AcceptsReturn
            AddHandler .CheckedChanged, AddressOf AcceptsReturnChkBox_CheckedChanged
        End With


        ' Tab 入力を受け付けるか否か
        Dim acceptsTabChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(acceptsTabChkBox)
        With acceptsTabChkBox
            .Location = New Point(10, 35)
            .Text = "AcceptsTab"
            .Checked = Me.m_textBox.AcceptsTab
            AddHandler .CheckedChanged, AddressOf AcceptsTabChkBox_CheckedChanged
        End With


        ' BorderStyle の設定
        Dim borderStyleCombo As ComboBox = New ComboBox()
        textBoxSettingTabPage.Controls.Add(borderStyleCombo)
        With borderStyleCombo
            .Location = New Point(10, 60)
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.AddRange(New Object() {BorderStyle.Fixed3D, BorderStyle.FixedSingle, BorderStyle.None})
            .SelectedItem = Me.m_textBox.BorderStyle
            AddHandler .SelectedIndexChanged, AddressOf BorderStyleCombo_SelectecIndexChanged
        End With


        ' Focus を失った時に選択された文字をそのままにするか否か
        Dim hideSelectionChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(hideSelectionChkBox)
        With hideSelectionChkBox
            .AutoSize = True
            .Location = New Point(10, 85)
            .Text = "HideSelection"
            .Checked = Me.m_textBox.HideSelection
            AddHandler .CheckedChanged, AddressOf HideSelectionChkBox_CheckedChanged
        End With


        ' 複数行にするか否か
        Dim multilineChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(multilineChkBox)
        With multilineChkBox
            .AutoSize = True
            .Location = New Point(10, 110)
            .Text = "Multiline"
            .Checked = Me.m_textBox.Multiline
            AddHandler .CheckedChanged, AddressOf MultilineChkBox_CheckedChanged
        End With


        ' 文字をマスクするか否か
        Dim passwordCharChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(passwordCharChkBox)
        With passwordCharChkBox
            .AutoSize = True
            .Location = New Point(10, 135)
            .Text = "PasswordChar"
            .Checked = (Me.m_textBox.PasswordChar <> Nothing)
            AddHandler .CheckedChanged, AddressOf PasswordCharChkBox_CheckedChanged
        End With


        ' 読み取り専用にするか否か
        Dim readonlyChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(readonlyChkBox)
        With readonlyChkBox
            .AutoSize = True
            .Location = New Point(10, 160)
            .Text = "ReadOnly"
            .Checked = Me.m_textBox.ReadOnly
            AddHandler .CheckedChanged, AddressOf ReadonlyChkBox_CheckedChanged
        End With


        ' ショートカットを使用可能にするか否か
        Dim shortcutsEnabledChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(shortcutsEnabledChkBox)
        With shortcutsEnabledChkBox
            .AutoSize = True
            .Location = New Point(10, 185)
            .Text = "ShortcutsEnabled"
            .Checked = Me.m_textBox.ShortcutsEnabled
            AddHandler .CheckedChanged, AddressOf ShortcutsEnabled_CheckedChanged
        End With


        ' カーソルを最後に持っていくか否か
        Dim moveCursorChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(moveCursorChkBox)
        With moveCursorChkBox
            .AutoSize = True
            .Location = New Point(10, 210)
            .Text = "カーソルを最後に持っていくか否か"
            .Checked = Me.m_moveCursor
            AddHandler .CheckedChanged, AddressOf MoveCursorChkBox_CheckedChanged
        End With


        ' 既定のパスワード文字を表示するか否か
        Dim useSystemPasswordCharChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(useSystemPasswordCharChkBox)
        With useSystemPasswordCharChkBox
            .AutoSize = True
            .Location = New Point(10, 235)
            .Text = "UseSystemPassword"
            .Checked = Me.m_textBox.UseSystemPasswordChar
            AddHandler .CheckedChanged, AddressOf UseSystemPasswordChar_CheckedChanged
        End With


        ' ワードラップするか否か
        Dim wordWrapChkBox As CheckBox = New CheckBox()
        textBoxSettingTabPage.Controls.Add(wordWrapChkBox)
        With wordWrapChkBox
            .AutoSize = True
            .Location = New Point(10, 260)
            .Text = "WordWrap"
            .Checked = Me.m_textBox.WordWrap
            AddHandler .CheckedChanged, AddressOf WordWrap_CheckedChanged
        End With


        ' AutoComplete の設定
        With Me.m_textBox
            .AutoCompleteMode = AutoCompleteMode.Suggest
            .AutoCompleteSource = AutoCompleteSource.CustomSource
            .AutoCompleteCustomSource.AddRange(New String() {"ふじこ", "エデン", "オット"})
        End With


        Me.Size = New Size(Me.Width, 350)
    End Sub


    Private Sub AcceptsReturnChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.AcceptsReturn = chk.Checked
    End Sub


    Private Sub AcceptsTabChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.AcceptsTab = chk.Checked
    End Sub


    Private Sub BorderStyleCombo_SelectecIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim cmb As ComboBox = DirectCast(sender, ComboBox)
        Me.m_textBox.BorderStyle = DirectCast(cmb.SelectedItem, BorderStyle)
    End Sub


    Private Sub HideSelectionChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.HideSelection = chk.Checked
    End Sub


    Private Sub MultilineChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        If chk.Checked Then
            Me.m_textBox.Dock = DockStyle.Fill
            Me.m_textBox.ScrollBars = ScrollBars.Both
        Else
            Me.m_textBox.Dock = DockStyle.Top
            Me.m_textBox.ScrollBars = ScrollBars.None
        End If
        Me.m_textBox.Multiline = chk.Checked
    End Sub


    Private Sub PasswordCharChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        If chk.Checked Then
            ' PasswordChar に何か値を設定すれば勝手にマスクされる
            Me.m_textBox.PasswordChar = "@"c
        Else
            Me.m_textBox.PasswordChar = Nothing
        End If
    End Sub


    Private Sub ReadonlyChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.ReadOnly = chk.Checked
    End Sub


    Private Sub ShortcutsEnabled_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.ShortcutsEnabled = chk.Checked
    End Sub


    Private Sub MoveCursorChkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_moveCursor = chk.Checked
    End Sub


    Private Sub TextBox_Enter(ByVal sender As Object, ByVal e As EventArgs)
        If Me.m_moveCursor Then
            ' 文字の最後にカーソルを持っていく
            Me.m_textBox.SelectionLength = 0
            Me.m_textBox.SelectionStart = Me.m_textBox.TextLength + 1
        End If
    End Sub


    Private Sub UseSystemPasswordChar_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.UseSystemPasswordChar = chk.Checked
    End Sub


    Private Sub WordWrap_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim chk As CheckBox = DirectCast(sender, CheckBox)
        Me.m_textBox.WordWrap = chk.Checked
    End Sub


    Private Sub TextBox_Leave(ByVal sender As Object, ByVal e As EventArgs)
        Dim inputedText As String() = Me.m_textBox.Lines
        For Each text As String In inputedText
            Console.WriteLine(text)
        Next
    End Sub
End Class

TableLayoutPanel（System.Windows.Forms.TableLayoutPanel）

Wed, 25 Apr 2007 12:00:00 GMT

こいつも存在は知ってるけど使う機会がなかったです。
Panel を継承して、IExtenderProvider を実装しているのか。へー。

で、TableLayoutPanel コントロールの推奨される手順を眺めているとイロイロと非おススメ事項があるのが解ります。
・単純な画面には TableLayoutPanel 使ってもあまり有効ではない。
・PropertyGrid 等の画面は一般的に 1 個のでっかいコントロールを画面に張り付けるので、
　ほかのコントロールの入る余地がないから意味ない。
・Dock プロパティは Fill にするべからず（メリットないから）
・入れ子にするべからず（パフォーマンスの低下）
・ビジュアル継承するべからず（パフォーマンスの低下）

じゃあ、どんな画面に向いてるのかっていうと
・フォームが複数の部分から成り、それぞれを比例的にサイズ変更する必要があるレイアウト。
　→具体的にはどんなの？ちょっとイメージが湧きませんでした。
・レイアウトが動的に生成される場合
・ローカライズ等で文字幅が変わる可能性がある場合

あんまり使い道ないじゃん...
じゃ、MS のサンプル見てみよう！ということで方法 : データ入力用のサイズ変更可能な Windows フォームを作成するを実行した画像をのっけてみました。

■参考文献
TableLayoutPanel クラス
 TableLayoutPanel コントロール (Windows フォーム)

■実行画像
方法 : データ入力用のサイズ変更可能な Windows フォームを作成するのフォーム。今回はみんな画像がでっかくてスミマセン。。。

上記フォームを縮小したところ

自分でいじくってみた画面

■ユーザーコントロールのコード

'' 自身の Anchor または Dock を設定可能なユーザーコントロール
< Global.Microsoft.VisualBasic.CompilerServices.DesignerGenerated() > _
Partial Class TableLayoutPanelChild
    Inherits System.Windows.Forms.UserControl


    'UserControl はコンポーネント一覧をクリーンアップするために dispose をオーバーライドします。
    < System.Diagnostics.DebuggerNonUserCode() > _
    Protected Overrides Sub Dispose(ByVal disposing As Boolean)
        Try
            If disposing AndAlso components IsNot Nothing Then
                components.Dispose()
            End If
        Finally
            MyBase.Dispose(disposing)
        End Try
    End Sub


    'Windows フォーム デザイナで必要です。
    Private components As System.ComponentModel.IContainer


    'メモ: 以下のプロシージャは Windows フォーム デザイナで必要です。
    'Windows フォーム デザイナを使用して変更できます。  
    'コード エディタを使って変更しないでください。
    < System.Diagnostics.DebuggerStepThrough() > _
    Private Sub InitializeComponent()
        Me.ComboBox1 = New System.Windows.Forms.ComboBox
        Me.ComboBox2 = New System.Windows.Forms.ComboBox
        Me.SuspendLayout()
        '
        'ComboBox1
        '
        Me.ComboBox1.FormattingEnabled = True
        Me.ComboBox1.Location = New System.Drawing.Point(3, 3)
        Me.ComboBox1.Name = "ComboBox1"
        Me.ComboBox1.Size = New System.Drawing.Size(121, 20)
        Me.ComboBox1.TabIndex = 0
        '
        'ComboBox2
        '
        Me.ComboBox2.FormattingEnabled = True
        Me.ComboBox2.Location = New System.Drawing.Point(3, 29)
        Me.ComboBox2.Name = "ComboBox2"
        Me.ComboBox2.Size = New System.Drawing.Size(121, 20)
        Me.ComboBox2.TabIndex = 1
        '
        'TableLayoutPanelChild
        '
        Me.AutoScaleDimensions = New System.Drawing.SizeF(6.0!, 12.0!)
        Me.AutoScaleMode = System.Windows.Forms.AutoScaleMode.Font
        Me.Controls.Add(Me.ComboBox2)
        Me.Controls.Add(Me.ComboBox1)
        Me.Name = "TableLayoutPanelChild"
        Me.Size = New System.Drawing.Size(129, 52)
        Me.ResumeLayout(False)


    End Sub
    Friend WithEvents ComboBox1 As System.Windows.Forms.ComboBox
    Friend WithEvents ComboBox2 As System.Windows.Forms.ComboBox


    Private Sub TableLayoutPanelChild_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        With Me.ComboBox1
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.Add(AnchorStyles.Bottom)
            .Items.Add(AnchorStyles.Left)
            .Items.Add(AnchorStyles.None)
            .Items.Add(AnchorStyles.Right)
            .Items.Add(AnchorStyles.Top)
            .SelectedItem = .Anchor
        End With


        With Me.ComboBox2
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.Add(DockStyle.Bottom)
            .Items.Add(DockStyle.Fill)
            .Items.Add(DockStyle.Left)
            .Items.Add(DockStyle.None)
            .Items.Add(DockStyle.Right)
            .Items.Add(DockStyle.Top)
            .SelectedItem = .Dock
        End With
    End Sub
    Private Sub ComboBox1_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ComboBox1.SelectedIndexChanged
        Me.Anchor = DirectCast(Me.ComboBox1.SelectedItem, AnchorStyles)
    End Sub
    Private Sub ComboBox2_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles ComboBox2.SelectedIndexChanged
        Me.Dock = DirectCast(Me.ComboBox2.SelectedItem, DockStyle)
    End Sub


End Class

■Form のコード

Public Class TableLayoutPanelTest


    Private m_table As TableLayoutPanel


    Private Sub TableLayoutPanelTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Dim children As List(Of TableLayoutPanelChild) = New List(Of TableLayoutPanelChild)
        children.AddRange(Me.CreateChildren(4, Color.LightSalmon))
        children.AddRange(Me.CreateChildren(4, Color.LightYellow))
        children.AddRange(Me.CreateChildren(4, Color.LightGreen))
        children.AddRange(Me.CreateChildren(4, Color.LightBlue))


        Dim context As ContextMenuStrip = New ContextMenuStrip()
        Dim menuItem As ToolStripComboBox = New ToolStripComboBox()
        With menuItem
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.Add(TableLayoutPanelCellBorderStyle.Inset)
            .Items.Add(TableLayoutPanelCellBorderStyle.InsetDouble)
            .Items.Add(TableLayoutPanelCellBorderStyle.None)
            .Items.Add(TableLayoutPanelCellBorderStyle.Outset)
            .Items.Add(TableLayoutPanelCellBorderStyle.OutsetDouble)
            .Items.Add(TableLayoutPanelCellBorderStyle.OutsetPartial)
            .Items.Add(TableLayoutPanelCellBorderStyle.Single)
            .SelectedItem = TableLayoutPanelCellBorderStyle.Inset


            AddHandler .SelectedIndexChanged, AddressOf CellBorderStyleCombo_SelectedIndexChanged
        End With
        context.Items.Add(menuItem)


        Me.m_table = New TableLayoutPanel()
        Me.Controls.Add(Me.m_table)
        With Me.m_table
            .Anchor = CType((((System.Windows.Forms.AnchorStyles.Top Or System.Windows.Forms.AnchorStyles.Bottom) _
                    Or System.Windows.Forms.AnchorStyles.Left) _
                    Or System.Windows.Forms.AnchorStyles.Right), System.Windows.Forms.AnchorStyles)
            .ContextMenuStrip = context
            .CellBorderStyle = TableLayoutPanelCellBorderStyle.Inset
            .Size = New Size(250, 250)
            .AutoSize = True


            ' 列
            .ColumnCount = 4
            .ColumnStyles.Add(New ColumnStyle())
            .ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0F))
            .ColumnStyles.Add(New ColumnStyle())
            .ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0F))


            ' 行
            .RowCount = 4
            .RowStyles.Add(New RowStyle())
            .RowStyles.Add(New RowStyle(SizeType.Percent, 50.0F))
            .RowStyles.Add(New RowStyle())
            .RowStyles.Add(New RowStyle(SizeType.Percent, 50.0F))


            ' Cell に 子コントロールを埋め込む
            Dim itemIndex As Integer = 0
            For columnIndex As Integer = 0 To .ColumnCount - 1
                For rowIndex As Integer = 0 To .RowCount - 1
                    .Controls.Add(children(itemIndex), columnIndex, rowIndex)
                    itemIndex += 1
                Next
            Next


            ' セルの再描画
            AddHandler .CellPaint, AddressOf CellPaint
        End With


        Me.Size = New Size(500, 500)
    End Sub


    Private Sub CellPaint(ByVal sender As Object, ByVal e As TableLayoutCellPaintEventArgs)
        Console.WriteLine("CellPaint(" & e.Column.ToString() & _
                          "," & e.Row.ToString() & ")")
    End Sub


    Private Sub CellBorderStyleCombo_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        ' セルの境界線スタイルを変更
        Me.m_table.CellBorderStyle = _
        DirectCast(DirectCast(sender, ToolStripComboBox).SelectedItem, TableLayoutPanelCellBorderStyle)
    End Sub


    Private Function CreateChildren(ByVal count As Integer, ByVal setColor As Color) As List(Of TableLayoutPanelChild)
        Dim lst As List(Of TableLayoutPanelChild) = New List(Of TableLayoutPanelChild)
        For counter As Integer = 0 To count - 1
            Dim child As TableLayoutPanelChild = New TableLayoutPanelChild()
            If (counter + 1) Mod 2 = 0 Then
                child.BackColor = setColor
            Else
                child.BackColor = color.White
            End If
            lst.Add(child)
        Next
        Return lst
    End Function
End Class

TabControl（System.Windows.Forms.TabControl）

Tue, 24 Apr 2007 12:36:00 GMT

また間があいちゃいました。
TabControl も、この一連の勉強の中で無理やり盛り込んだ感があるので
いまさらという感じもしないではないですが、一応。

HotTrack プロパティがびみょー。
強調表示されると書いてありますが、私の環境だと色が青っぽくなってるかな？
そう言われればそうかな？
色は「ローカルコンピュータのシステムカラーによって決まります。」とあるので
コントロールパネル→画面→デザイン→テーマで設定されている色
が適用されているわけですね。ふむふむ。

ということは、システムカラーを変えたくないけど、ここは好きな色にしたいという場合は
継承して自分で実装するしかないみたいです。

■参考文献
TabControl クラス
 TabControl コントロール (Windows フォーム)

■実行画像
なんだか TabControl ではないように見えますが、一応 SplitContainer の下のほうにあるのは TabControl です。

Public Class TabControlTest


    Private Sub TabControlTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        Me.Size = New Size(250, 400)
        ' SplitContainer を配置
        Dim splitCntner As SplitContainer = New SplitContainer()
        Me.Controls.Add(splitCntner)
        With splitCntner
            .Dock = DockStyle.Fill
            .SplitterWidth = 5
            .SplitterDistance = 80
            .BorderStyle = BorderStyle.Fixed3D
            .Orientation = Orientation.Horizontal
        End With
        splitCntner.Dock = DockStyle.Fill


        ' DrawMode を動的に変える
        Dim drawModeCombo As ComboBox = New ComboBox()
        splitCntner.Panel1.Controls.Add(drawModeCombo)
        With drawModeCombo
            .Dock = DockStyle.Top
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.AddRange(New Object() {TabDrawMode.Normal, TabDrawMode.OwnerDrawFixed})
            AddHandler .SelectedIndexChanged, AddressOf OnDrawModeCombo_SelectedIndexChanged
        End With


        ' Appearance を動的に変える
        Dim appearanceCombo As ComboBox = New ComboBox()
        splitCntner.Panel1.Controls.Add(appearanceCombo)
        With appearanceCombo
            .Dock = DockStyle.Top
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.AddRange(New Object() {TabAppearance.Buttons, TabAppearance.FlatButtons,TabAppearance.Normal})
            AddHandler .SelectedIndexChanged, AddressOf OnappearanceCombo_SelectedIndexChanged
        End With


        ' Alignment を動的に変える
        Dim alignmentCombo As ComboBox = New ComboBox()
        splitCntner.Panel1.Controls.Add(alignmentCombo)
        With alignmentCombo
            .Dock = DockStyle.Top
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.AddRange(New Object() {TabAlignment.Bottom, TabAlignment.Left, TabAlignment.Right, TabAlignment.top})
            AddHandler .SelectedIndexChanged, AddressOf OnAlignmentCombo_SelectedIndexChanged
        End With


        ' ImageList の設定
        Dim imgLst As ImageList = New ImageList()
        With imgLst
            .ImageSize = New Size(20, 20)
            .Images.Add(My.Resources.wankuma.ToString(), My.Resources.wankuma)
            .Images.Add(My.Resources.blackwankuma.ToString(), My.Resources.blackwankuma)
        End With


        Dim tabCtrl As TabControl = New TabControl()
        splitCntner.Panel2.Controls.Add(tabCtrl)
        With tabCtrl
            .Dock = DockStyle.Fill
            .Alignment = TabAlignment.Left
            .DrawMode = TabDrawMode.Normal
            .Appearance = TabAppearance.Normal
            .ImageList = imgLst
            .Multiline = True
            .ShowToolTips = True
            .ItemSize = New Size(100, 100) ' タブの大きさを設定（通常は自動調整）
            .HotTrack = True ' マウスをタブに置いたときにテキストの強調


            ' DrawMode が OwnerDraw 時
            AddHandler .DrawItem, AddressOf TabControl_DrawItem


            AddHandler .Deselected, AddressOf TabControl_Deselected
            AddHandler .Deselecting, AddressOf TabControl_Deselecting
            AddHandler .Selected, AddressOf TabControl_Selected
            AddHandler .Selecting, AddressOf TabControl_Selecting
        End With
        ' ToolTip の設定
        Dim tip As ToolTip = New ToolTip()
        tip.SetToolTip(tabCtrl, "ToolTip")


        drawModeCombo.SelectedItem = tabCtrl.DrawMode
        appearanceCombo.SelectedItem = tabCtrl.Appearance
        alignmentCombo.SelectedItem = tabCtrl.Alignment


        ' TabPage の追加
        Dim wankumaPage As TabPage = New TabPage("wankuma")
        wankumaPage.ImageIndex = 0
        Dim blackWankumaPage As TabPage = New TabPage("blackWankuma")
        blackWankumaPage.ImageIndex = 1
        With tabCtrl.TabPages
            .Clear()
            .AddRange(New TabPage() {wankumaPage, blackWankumaPage})
        End With
    End Sub


    Private Sub TabControl_DrawItem(ByVal sender As Object, ByVal e As DrawItemEventArgs)
        Dim tabCtrl As TabControl = DirectCast(sender, TabControl)


        Dim rect As Rectangle = tabCtrl.GetTabRect(e.Index)
        '背景の描画
        Using brush As System.Drawing.Drawing2D.LinearGradientBrush _
                       = New System.Drawing.Drawing2D.LinearGradientBrush(rect, Color.White, Color.LightCoral, 0.0F)
            e.Graphics.FillRectangle(brush, rect)
        End Using


        '文字の描画
        Dim format As StringFormat = New StringFormat()
        format.LineAlignment = StringAlignment.Center
        format.Alignment = StringAlignment.Far
        Dim text As String = tabCtrl.TabPages(e.Index).Text
        Using valueBrush As SolidBrush = New SolidBrush(SystemColors.ControlText)
            e.Graphics.DrawString(text, tabCtrl.TabPages(e.Index).Font, valueBrush, rect)
        End Using
    End Sub


    Private Sub OnDrawModeCombo_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim combo As ComboBox = DirectCast(sender, ComboBox)
        Dim drawMode As TabDrawMode = DirectCast(combo.SelectedItem, TabDrawMode)
        Dim splitCntner As SplitContainer = DirectCast(combo.Parent.Parent, SplitContainer)
        Dim tabCtrl As TabControl = DirectCast(splitCntner.Panel2.Controls(0), TabControl)
        tabCtrl.DrawMode = drawMode
    End Sub


    Private Sub OnAppearanceCombo_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim combo As ComboBox = DirectCast(sender, ComboBox)
        Dim appearance As TabAppearance = DirectCast(combo.SelectedItem, TabAppearance)
        Dim splitCntner As SplitContainer = DirectCast(combo.Parent.Parent, SplitContainer)
        Dim tabCtrl As TabControl = DirectCast(splitCntner.Panel2.Controls(0), TabControl)
        tabCtrl.Appearance = appearance
    End Sub


    Private Sub OnAlignmentCombo_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim combo As ComboBox = DirectCast(sender, ComboBox)
        Dim alignment As TabAlignment = DirectCast(combo.SelectedItem, TabAlignment)
        Dim splitCntner As SplitContainer = DirectCast(combo.Parent.Parent, SplitContainer)
        Dim tabCtrl As TabControl = DirectCast(splitCntner.Panel2.Controls(0), TabControl)
        tabCtrl.Alignment = alignment
    End Sub


    '' Deselect/Select
    Private Sub TabControl_Deselected(ByVal sender As Object, ByVal e As TabControlEventArgs)
        Console.WriteLine(StrDup(10, "="c) & ControlChars.NewLine & "Deselected" & ControlChars.NewLine & StrDup(10, "="c))
        Console.WriteLine("Action:" & e.Action.ToString())
        Console.WriteLine("TabPage:" & e.TabPage.Text)
        Console.WriteLine("TabPageIndex:" & e.TabPageIndex.ToString())
    End Sub


    Private Sub TabControl_Deselecting(ByVal sender As Object, ByVal e As TabControlCancelEventArgs)
        'e.Cancel = True キャンセル可能
        Console.WriteLine(StrDup(10, "="c) & ControlChars.NewLine & "Deselecting" & ControlChars.NewLine & StrDup(10, "="c))
        Console.WriteLine("Action:" & e.Action.ToString())
        Console.WriteLine("TabPage:" & e.TabPage.Text)
        Console.WriteLine("TabPageIndex:" & e.TabPageIndex.ToString())
    End Sub


    Private Sub TabControl_Selected(ByVal sender As Object, ByVal e As TabControlEventArgs)
        Console.WriteLine(StrDup(10, "="c) & ControlChars.NewLine & "Selected" & ControlChars.NewLine & StrDup(10, "="c))
        Console.WriteLine("Action:" & e.Action.ToString())
        Console.WriteLine("TabPage:" & e.TabPage.Text)
        Console.WriteLine("TabPageIndex:" & e.TabPageIndex.ToString())
    End Sub


    Private Sub TabControl_Selecting(ByVal sender As Object, ByVal e As TabControlCancelEventArgs)
        'e.Cancel = True キャンセル可能
        Console.WriteLine(StrDup(10, "="c) & ControlChars.NewLine & "Selecting" & ControlChars.NewLine & StrDup(10, "="c))
        Console.WriteLine("Action:" & e.Action.ToString())
        Console.WriteLine("TabPage:" & e.TabPage.Text)
        Console.WriteLine("TabPageIndex:" & e.TabPageIndex.ToString())
    End Sub
End Class

StatusStrip（System.Windows.Forms.StatusStrip）

Fri, 06 Apr 2007 10:33:00 GMT

専業主婦には新年度なんて全然関係ないんですが、
なんだか春はだるくてうだうだしてたら blog の更新を忘れていました。
来週は来週で勉強会の準備があるので、うだうだ遊んだり勉強したりするペースも落ちそうな感じがします。

StatusStrip はあまり使う機会がなかったですけど
StatusBar よりもでざいなでちょちょっといじると簡単に実装できちゃうのはよさげな感じっすね。
自前のコントロールをぶち込むのも楽な感じ。

ToolStripDropDownButton と ToolStripSplitButton
で一見なにが違うのか全然わからんかったんですが、
よくよく見ると異なるコントロールである事が解りました。

■参考文献
StatusStrip クラス

■実行画像
100 % になると黒いわんくまさんではなく通常のわんくまさんになります。

Public Class StatusStripTest


    Private Const LABEL_NAME As String = "statusLabel"
    Private Const PROGRESS_NAME As String = "statusProgressBar"
    Private Const IMAGE_NAME As String = "statusImage"


    Private Sub StatusStripTest_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load


        With Me.StatusStrip1
            ' オーバーフロー機能をサポート
            .CanOverflow = True
            ' ToolTip を表示する
            .ShowItemToolTips = True
            ' コンテナの端から端まで拡大する
            .Stretch = True
        End With


        ' Label の追加
        Dim statusLabel As ToolStripStatusLabel = New ToolStripStatusLabel()
        Me.StatusStrip1.Items.Add(statusLabel)
        With statusLabel
            .Name = LABEL_NAME
            .AutoToolTip = True
            .Text = String.Empty
            .ToolTipText = "進捗状況"
        End With


        ' ProgressBar の追加
        Dim statusProgressBar As ToolStripProgressBar = New ToolStripProgressBar()
        Me.StatusStrip1.Items.Add(statusProgressBar)
        With statusProgressBar
            .Name = PROGRESS_NAME
            .Value = 0
            .Minimum = 0
            .Maximum = 100
            .AutoToolTip = True
            .ToolTipText = "プログレスバーですよー"
        End With
        ' 無駄に非同期の仕事をさせる
        Dim bk As System.ComponentModel.BackgroundWorker = New System.ComponentModel.BackgroundWorker()
        bk.WorkerReportsProgress = True
        AddHandler bk.DoWork, AddressOf BackgroundWorker1_DoWork
        AddHandler bk.ProgressChanged, AddressOf BackgroundWorker1_ProgressChanged
        AddHandler bk.RunWorkerCompleted, AddressOf BackgroundWorker1_RunWorkerCompleted
        bk.RunWorkerAsync()


        ' Image の追加(カスタムコントロール。別にこんなん作らなくったって Label とかできますが。。。)
        Dim statusImage As ToolStripImage = New ToolStripImage()
        Me.StatusStrip1.Items.Add(statusImage)
        With statusImage
            .Name = IMAGE_NAME
            .PictureBox.Image = My.Resources.blackwankuma
            .ToolTipText = "イメージですよー"
        End With


        ' DropDown の追加
        Dim statusDropDown As ToolStripDropDownButton = New ToolStripDropDownButton()
        Me.StatusStrip1.Items.Add(statusDropDown)
        With statusDropDown
            .Text = "ドロップダウンー"
            .AutoToolTip = True
            .ToolTipText = "ドロップダウンー"
            ' マージンを非表示にする
            DirectCast(.DropDown, ToolStripDropDownMenu).ShowImageMargin = False
            .DropDownItems.AddRange(New ToolStripItem() { _
                                    New ToolStripLabel("eden"), _
                                    New ToolStripLabel("fujiko")})
        End With


        ' SplitButton の追加
        Dim statusSplitButton As ToolStripSplitButton = New ToolStripSplitButton()
        Me.StatusStrip1.Items.Add(statusSplitButton)
        With statusSplitButton
            .Text = "SplitButton"
            .AutoToolTip = True
            .ToolTipText = "SplitButton"
            .TextImageRelation = TextImageRelation.ImageBeforeText
            ' マージンを非表示にする
            DirectCast(.DropDown, ToolStripDropDownMenu).ShowImageMargin = False
            .DropDownItems.AddRange(New ToolStripItem() { _
                                         New ToolStripButton("eden", My.Resources.えでんさん), _
                                         New ToolStripButton("fujiko", My.Resources.ふじこちゃん)})
        End With


        ' GlipStyle や LayoutStyle を動的に変えてみる
        Dim glipStyleCombo As ComboBox = New ComboBox()
        Me.Controls.Add(glipStyleCombo)
        With glipStyleCombo
            .Location = New Point(10, 10)
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.Add(ToolStripGripStyle.Hidden)
            .Items.Add(ToolStripGripStyle.Visible)
            .SelectedItem = Me.StatusStrip1.GripStyle


            AddHandler .SelectedIndexChanged, AddressOf GlipStyleComboBox_SelectedIndexChanged
        End With


        Dim layoutStyleCombo As ComboBox = New ComboBox()
        Me.Controls.Add(layoutStyleCombo)
        With layoutStyleCombo
            .Location = New Point(10, 30)
            .Size = New Size(200, .Size.Height)
            .DropDownStyle = ComboBoxStyle.DropDownList
            .Items.Add(ToolStripLayoutStyle.Flow)
            .Items.Add(ToolStripLayoutStyle.HorizontalStackWithOverflow)
            .Items.Add(ToolStripLayoutStyle.StackWithOverflow)
            .Items.Add(ToolStripLayoutStyle.Table)
            .Items.Add(ToolStripLayoutStyle.VerticalStackWithOverflow)
            .SelectedItem = Me.StatusStrip1.LayoutStyle


            AddHandler .SelectedIndexChanged, AddressOf LayoutStyleComboBox_SelectedIndexChanged
        End With
    End Sub


    Private Sub GlipStyleComboBox_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim selectedGrip As ToolStripGripStyle = DirectCast(DirectCast(sender, ComboBox).SelectedItem, ToolStripGripStyle)
        Me.StatusStrip1.GripStyle = selectedGrip
    End Sub


    Private Sub LayoutStyleComboBox_SelectedIndexChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim selectedLayout As ToolStripLayoutStyle = DirectCast(DirectCast(sender, ComboBox).SelectedItem, ToolStripLayoutStyle)
        Me.StatusStrip1.LayoutStyle = selectedLayout
    End Sub
    '' 無駄な非同期のお仕事関連
    Private Sub BackgroundWorker1_DoWork(ByVal sender As System.Object, ByVal e As System.ComponentModel.DoWorkEventArgs)
        Dim bk As System.ComponentModel.BackgroundWorker = _
        DirectCast(sender, System.ComponentModel.BackgroundWorker)
        For counter As Integer = 0 To 100
            System.Threading.Thread.Sleep(100)
            bk.ReportProgress(counter)
        Next
    End Sub


    Private Sub BackgroundWorker1_ProgressChanged(ByVal sender As Object, ByVal e As System.ComponentModel.ProgressChangedEventArgs)
        ' 状況の表示
        Dim statusProgressBar As ToolStripProgressBar = DirectCast(Me.StatusStrip1.Items(PROGRESS_NAME), ToolStripProgressBar)
        statusProgressBar.Value = e.ProgressPercentage
        Dim statusLabel As ToolStripStatusLabel = DirectCast(Me.StatusStrip1.Items(LABEL_NAME), ToolStripStatusLabel)
        statusLabel.Text = e.ProgressPercentage.ToString() & " %"
    End Sub


    Private Sub BackgroundWorker1_RunWorkerCompleted(ByVal sender As Object, ByVal e As System.ComponentModel.RunWorkerCompletedEventArgs)
        If Not e.Cancelled AndAlso e.Error Is Nothing Then
            ' 100 % になったら、イメージの差し替え
            Dim statusImage As ToolStripImage = DirectCast(Me.StatusStrip1.Items(IMAGE_NAME), ToolStripImage)
            statusImage.PictureBox.Image = My.Resources.wankuma
        End If
    End Sub
End Class


Public Class ToolStripImage
    Inherits ToolStripControlHost


    Public ReadOnly Property PictureBox() As PictureBox
        Get
            Return DirectCast(MyBase.Control, PictureBox)
        End Get
    End Property


    Public Sub New()
        MyBase.New(New PictureBox())
    End Sub
End Class