なんかおかしいトコまだありそう･･･。orz
Namespace Torikobito.WankumaFestival.No1
Public Class Calculator
Public Sub New()
Me.Initialize()
End Sub
Public Sub Initialize()
Me.DisplayText = "0"
Me._memo = Decimal.Zero
Me._operation = ArithmeticOperation.None
Me._nextInputIsNew = True
Me._isError = False
End Sub
Private _displayText As String
Public Property DisplayText() As String
Get
Return _displayText
End Get
Private Set(ByVal value As String)
_displayText = value
End Set
End Property
Private Shared ReadOnly _validInputNumbers As Decimal() = {1D, 2D, 3D, 4D, 5D, 6D, 7D, 8D, 9D, 0D}
Public Shared ReadOnly Property ValidInputNumbers() As System.Collections.ObjectModel.ReadOnlyCollection(Of Decimal)
Get
Return New System.Collections.ObjectModel.ReadOnlyCollection(Of Decimal)(Calculator._validInputNumbers)
End Get
End Property
Public Sub InputNumber(ByVal number As Decimal)
If Me._isError Then
Exit Sub
End If
If Not Calculator.ValidInputNumbers.Contains(number) Then
Exit Sub
End If
Dim newText As String
If Me._nextInputIsNew Then
newText = "0"
Me._nextInputIsNew = False
Else
newText = Me.DisplayText
End If
If newText = "0" Then
newText = number.ToString
Else
newText &= number.ToString
End If
Dim parseValue As Decimal
If Decimal.TryParse(newText, parseValue) Then
Me.DisplayText = newText
End If
End Sub
Public Enum ArithmeticOperation
None
Addition
Subtraction
Multiplication
Division
End Enum
Private _memo As Decimal
Private _operation As Calculator.ArithmeticOperation
Private _nextInputIsNew As Boolean
Public Sub SetArithmeticOperation(ByVal op As Calculator.ArithmeticOperation)
If Me._isError Then
Exit Sub
End If
If Me._nextInputIsNew AndAlso Me._operation <> ArithmeticOperation.None Then
Me._operation = op
Exit Sub
End If
Me.Calculate()
If Not Me._isError Then
Me._memo = Decimal.Parse(Me.DisplayText)
Me._operation = op
Me._nextInputIsNew = True
End If
End Sub
Public Sub EndCalculation()
If Me._isError Then
Exit Sub
End If
Me.Calculate()
Me._memo = Decimal.Zero
Me._operation = ArithmeticOperation.None
Me._nextInputIsNew = True
End Sub
Private Sub Calculate()
If Me._isError Then
Exit Sub
End If
Dim errorMessage As String = String.Empty
Dim calcResult As Decimal
Dim current As Decimal
If Decimal.TryParse(Me.DisplayText, current) Then
Try
Select Case Me._operation
Case ArithmeticOperation.Addition
calcResult = Decimal.Add(Me._memo, current)
Case ArithmeticOperation.Subtraction
calcResult = Decimal.Subtract(Me._memo, current)
Case ArithmeticOperation.Multiplication
calcResult = Decimal.Multiply(Me._memo, current)
Case ArithmeticOperation.Division
If current = Decimal.Zero Then
Me._isError = True
errorMessage = "Divide By Zero !? (´д｀)"
Exit Select
End If
calcResult = Decimal.Divide(Me._memo, current)
Case Else
Exit Sub
End Select
Catch ex As System.OverflowException
Me._isError = True
errorMessage = "ヽ(`Д´)ﾉ Overflow!!"
End Try
Else
Me._isError = True
errorMessage = "?? (ﾟДﾟ≡ﾟДﾟ) ??"
End If
If Me._isError Then
Me.DisplayText = errorMessage
Else
Me.DisplayText = calcResult.ToString
End If
End Sub
Public Sub SetDecimalPoint()
If Me._isError Then
Exit Sub
End If
Dim newText As String
If Me._nextInputIsNew Then
newText = "0"
Me._nextInputIsNew = False
Else
newText = Me.DisplayText
End If
If newText.Contains(".") Then
Exit Sub
Else
newText &= "."
End If
Me.DisplayText = newText
End Sub
Public Sub Negate()
If Me._isError Then
Exit Sub
End If
Dim newText As String = Me.DisplayText
If newText = "0" Then
Exit Sub
End If
If newText.Contains("-") Then
newText = newText.Replace("-", String.Empty)
Else
newText = "-" & newText
End If
Dim parseValue As Decimal
If Decimal.TryParse(newText, parseValue) Then
Me.DisplayText = newText
End If
End Sub
Public Sub Clear()
Me.DisplayText = "0"
Me._memo = Decimal.Zero
Me._operation = ArithmeticOperation.None
Me._nextInputIsNew = True
Me._isError = False
End Sub
Private _isError As Boolean
End Class
End Namespace
おなか空いたー！