WSH/Windows Script

[WSH]Outlookのアドレス帳をnpopqのアドレス帳にエクスポートする

むたぐち（牟田口大介） — Tue, 12 Aug 2008 23:12:00 GMT

Const olFolderContacts = 10
Set Outlook = CreateObject("Outlook.Application")
Set Fs = CreateObject("Scripting.FileSystemObject")
Set ts = Fs.CreateTextFile("Address.lst")
For Each oItem In Outlook.GetNamespace("MAPI").GetDefaultFolder(olFolderContacts).Items
	If oItem.Email1Address<>"" Then
		ts.WriteLine oItem.Email1Address & vbTab & oItem.FullName
	End If
	If oItem.Email2Address<>"" Then
		ts.WriteLine oItem.Email2Address & vbTab & oItem.FullName
	End If
	If oItem.Email3Address<>"" Then
		ts.WriteLine oItem.Email3Address & vbTab & oItem.FullName
	End If
Next
ts.Close

さくっと。他のメーラーにも無論カスタマイズして使ってください。npopqのアドレス帳ほどシンプルなのはたぶんないと思いますがｗ（メールアドレス＜タブ＞名前）

[VBS] RSS2.0のpubDateを取得する関数

むたぐち（牟田口大介） — Thu, 03 Jul 2008 13:47:00 GMT

Function GetPubDate(dDate)
	days = Array("","Sun","Mon","Tue","Wed","Thu","Fri","Sat")
	months = Array("","Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")
	GetPubDate = days(WeekDay(dDate)) & ", " & Right("0" & Day(dDate),2) & " " & months(Month(dDate)) & " " & Year(dDate) & " " & Right("0" & Hour(dDate),2) & ":" &  Right("0" & Minute(dDate),2) & ":" & _
Right("0" & Second(dDate),2) & " +0900"
	'Wed, 05 Oct 2005 19:08:12 +0900
End Function

探してもなかったので書いてみました。ついでにRSS1.0のdc:Dateも

Function GetDCDate(dDate)
	GetDCDate=Year(dDate) & "-" & Right("0" & Month(dDate),2) & "-" & Right("0" & Day(dDate),2) & "T" & _
	Right("0" & Hour(dDate),2) & ":" &  Right("0" & Minute(dDate),2) & ":" & _
	Right("0" & Second(dDate),2) & "+09:00"
	'2005-10-06T10:31:58+09:00
End Function

[Twitter][WSH]Twitterにポストする

むたぐち（牟田口大介） — Wed, 02 Jul 2008 20:48:00 GMT

Twitterに発言する最も簡単なスクリプトです。twitterPost.vbsと名前を付けて保存してください。

sUser = "*****" 'ユーザーID
sPassword = "*****" 'パスワード
sURL = "http://twitter.com/statuses/update.json"

Set oHTTP = WScript.CreateObject("Msxml2.XMLHTTP")
Set sc = CreateObject("ScriptControl")
sc.Language = "JScript"
Set js = sc.CodeObject

oHTTP.Open "POST", sURL, False, sUser, sPassword
oHTTP.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
oHTTP.setRequestHeader "X-Twitter-Client", "twitterPost.vbs"
oHTTP.setRequestHeader "X-Twitter-Client-Version", "1.0"
oHTTP.send "status=" & js.encodeURIComponent(WScript.Arguments(0))

使い方

twitterPost.vbs "テスト投稿"

WSH17回

むたぐち（牟田口大介） — Thu, 15 May 2008 20:48:00 GMT

FileSystemObjectオブジェクトを利用する（2）－＠IT http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh17/cformwsh17_01.html

WSH16回公開

むたぐち（牟田口大介） — Sun, 20 Apr 2008 20:33:00 GMT

FileSystemObjectオブジェクトを利用する（1）－＠IT
http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh16/cformwsh16_01.html

FSOですー

私流の切り口で説明しています
この説明展開どこかで見かけた方と思った方、するどいです
やはり私がFSOやると説明は同じになるんですね
私はこれが一番いい分類だと思っています

FSOは3回くらいに分けて解説します。

これが終わったら本連載は終了予定です。

次はー

未定ｗ

[Gadget補助][WSH]付箋の内容をテキストファイル化

むたぐち（牟田口大介） — Thu, 20 Mar 2008 20:18:00 GMT

Vistaガジェットに「付箋」というのがありますが、その内容をテキストに書き出すスクリプトをWSHで書いてみました。（22:55 WshNetworkを使ってAddDataパスを取得していたのをShell.Application経由で取得に変更）

'sTextFolderにVistaガジェット付箋をページごとに0.txt, 1.txt...のように保存していく
sTextFolder = "D:\document\Advanced_es の文書\" 'テキストファイル保存フォルダ
Set Fs = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("Shell.Application")
Const CSIDL_LOCAL_APPDATA  = &H1C
Set tsIni = Fs.OpenTextFile(Fs.BuildPath(objShell.NameSpace(CSIDL_LOCAL_APPDATA).Self.Path, _
            "\Microsoft\Windows Sidebar\Settings.ini"),,,True)
Set regEx = New RegExp
regEx.Global = True
bCNotesSection = False
Do Until tsIni.AtEndOfStream
    sLine = tsIni.ReadLine()
    If InStr(sLine,"CNotes.Gadget") Then
        bCNotesSection = True
    End If
    If bCNotesSection And InStr(sLine,"[") Then
        bCNotesSection = False
    End If
    If bCNotesSection Then
        regEx.Pattern = "(\d+)\=""(.+)"""
        If regEx.Test(sLine) Then
            For Each oMatch In regEx.Execute(sLine)
                Set oSubs = oMatch.SubMatches
                Fs.CreateTextFile(sTextFolder & oSubs(0) & ".txt").Write unescape(oSubs(1))
            Next
        End If
    End If
Loop
tsIni.Close

私はこのスクリプトをタスクスケジューラで5分間隔で動かしています。Advanced esというスマートフォンを使ってますが、これにViewTextというTodayプラグインを使うとテキストファイルがTodayに表示できるので、同期センターを使うと付箋の内容を同期できるわけです。

WSH連載15回公開

むたぐち（牟田口大介） — Thu, 21 Feb 2008 18:22:00 GMT

本業もやってます。

WshNetworkオブジェクトを利用する－＠IT
http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh15/cformwsh15_01.html

あまり目立たないオブジェクトですのでひっそりと一回分で書き上げました。

WSH Remoteについては初心者向けの範囲を逸脱すると編集さんと私の意見が一致したので省略することになりました。なんせ動作させるのにレジストリ操作やコマンドライン操作やDCOMの設定やWindows ファイアウォールの設定などが必要になってくるので動かすまでがたいへん。うちのWikiなどをどうぞ参考になさってください。

なので、次はFileSystemObjectです。WMIやADSIは今回やらないのでいよいよ佳境ですね。

[記事]最も初心者向けの言語は「Visual Basic」――スクリプト復活へ

むたぐち（牟田口大介） — Tue, 05 Feb 2008 22:08:00 GMT

最も初心者向けの言語は「Visual Basic」――スクリプト復活へ－＠IT
http://www.atmarkit.co.jp/news/200802/04/vb.html

わんくまのほかの方も取り上げられていますがメモめも。

VBScript.NETは今のところありませんが、DLR上で動く未来のVBはスクリプト風味になる（orスクリプトとしても使える）ようになるみたいですね。

私はPowerShellと同時にDLRを追っていこうと思っています。やっぱり、お手軽言語があるのはうれしいものです。

WSH14回

むたぐち（牟田口大介） — Fri, 28 Dec 2007 15:12:00 GMT

WshShellオブジェクトを利用する（3）－＠IT
http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh14/cformwsh14_01.html

特に問題はない、と思います。

今年はみなさまにたいへんお世話になりました。2008年もどうぞよろしく。

WSH連載第13回公開

むたぐち（牟田口大介） — Wed, 28 Nov 2007 18:11:00 GMT

WshShellオブジェクトを利用する（2）－＠IT
http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh13/cformwsh13_01.html
公開になりましたー
今回はレジストリのお話。レジストリの構造の解説が結構占めてます。
WshShellではできなくてよく質問されることも付記しときました。
ネタは・・・ちょこっとｗ
だんだん仕込みづらくなってきてます。