ASP.NET

SqlDataReaderのGetSchemeTableで、余計な列(フィールド)まで取ってくるときがある。

Mr.T — Wed, 11 Feb 2009 11:48:00 GMT

Mr.Tです、こんにちは。

#.NetFrameWork2.0　, SQLServer 2005での環境です。

ちなみに、これではないみたいです。
[BUG] SqlDataReader の GetSchemaTable() が誤った列名を返す　http://support.microsoft.com/kb/307512/ja

SQLServerからデータを取得して、それをDataTableにセットしたい...でも、フィールドの情報はいちいち指定したくない

という場合に、SqlDataReader.GetSchemaTableによって、テーブルのフィールド情報を取得し、そのフィールド名と

型情報をとってきて、自動的にDataTableへ落とし込む、なんてことをしてたりしますか？

今じゃ古いやり方なのかもしれませんけど、まあベタな方法ですよね。

#それとも、もう、やらないのかなぁ。

この流れでいうと、まずはDataTaleを用意して、そこにカラムを追加し、データを突っ込むことになりますが、

カラムを用意する時点で、どうもエラーになる。それは、例えば、こんなソース。

Dim targetSchemeDataReader As SqlDataReader = Nothing
Dim targetScheme As DataTable
targetSchemeDataReader = targetSQLCommand.ExecuteReader(CommandBehavior.KeyInfo)
targetScheme = targetSchemeDataReader.GetSchemaTable

Dim fieldNameIndex As Integer = targetScheme.Columns("ColumnName").Ordinal
Dim typeIndex As Integer = targetScheme.Columns("DataType").Ordinal
Dim isHiddenIndex As Integer = targetScheme.Columns("IsHidden").Ordinal

For Each iRow As System.Data.DataRow In targetScheme.Rows
targetDataTable.Columns.Add(iRow.Item(fieldNameIndex).ToString, _　←ここでエラー
Type.GetType(CType(iRow.Item(typeIndex), Type).FullName))
Next

デバッグしてみると、ストアドプロシジャから返された結果に対して、意図していないフィールドまで

返されていることがわかり、そのフィールドのカラム名がだぶっている様子。

#ダブったのは今回のケースではそうなっただけ

Ｓｅｌｅｃｔで返す予定になっていたのは、４つのフィールドであるのに、スキーマ情報として取得されたときには、8つのフィールド名

ということで、なぜそんなものまで返されるのか正直わけがわからなかった。

で、調べたところ似たような現象のお方がいた。

http://www.devnewsgroups.net/group/microsoft.public.dotnet.framework.adonet/topic53804.aspx

なんじゃ、英語でわからんのだけども、ロバートという人こんなこといってます。

When you specify the CommandBehavior.KeyInfo option, Sql Server will
automatically return you the columns in your original select along with the
necessary additional columns needed to uniquely identify the rows returned.

SQLComman.ExeteReader(CommandBehavior.KeyInfo)を使うと、SQLServerは、

行を一意に識別するため、自動的にキー項目を追加する、みたいな感じですね。

これ、どこがソース（情報源）になっているのかわかりませんが、そう考えると納得できます。

さらに、上記の返答のRessには、

IsHiddenという項目があること

取得元がViewであるなら、WITH VIEW_METADATAをつけるとええよ

とか云ってます。

とりあえず、そういうことであれば列情報に違いがあるんじゃないかと思い、比較してみたところ、

メタデータにIsHiddenという項目があることがわかりました。

これを比較すると、こちらがSelect ・・・と指定したフィールドに対しては、True,書いてないフィールドはFalseが

返ってきています。

そういうわけで、ソースをこんな風に変更。

Dim targetSchemeDataReader As SqlDataReader = Nothing
Dim targetScheme As DataTable
targetSchemeDataReader = targetSQLCommand.ExecuteReader(CommandBehavior.KeyInfo)
targetScheme = targetSchemeDataReader.GetSchemaTable

Dim fieldNameIndex As Integer = targetScheme.Columns("ColumnName").Ordinal
Dim typeIndex As Integer = targetScheme.Columns("DataType").Ordinal
Dim isHiddenIndex As Integer = targetScheme.Columns("IsHidden").Ordinal ←追加

For Each iRow As System.Data.DataRow In targetScheme.Rows
    If CBool(iRow.Item(isHiddenIndex)) = False Then　←追加
        targetDataTable.Columns.Add(iRow.Item(fieldNameIndex).ToString, _
                        Type.GetType(CType(iRow.Item(typeIndex), Type).FullName))

    End If　←追加
Next

めでたく、必要な情報のみ取得できました。

って、KeyInfo使えっていってるのは、MSDNサンプルにもあるのに、どういうことなんじゃ！

DataReader の GetSchemaTable メソッドと Visual Basic .NET を使用して列スキーマを取得する方法

http://support.microsoft.com/kb/310108/ja

HttpServerUtility.Executeではクエリパラメータが渡せる

Mr.T — Wed, 07 Jan 2009 15:59:00 GMT

Mr.Tです、こんにちは。

レガシーのASPで、IIS5.0を使っていると、Server.Executeでページ遷移をすることがよくありましたが、

実はURLにクエリ文字列が含められなくて、非常に困っていました。

たとえば、

Server.Execute("hogehoge.asp?UserCD='**'")

みたいなものですね。これは、エラーになります。

⇒IIS の Server.Execute パラメータにクエリ文字列を使用するとエラーが発生する：http://support.microsoft.com/kb/247420/ja

これは、仕様なのでどうしようもなかったのですね。

ところが、ASP.NETになってから、Server.ExecuteメソッドはHttpServerutilityクラスになってくれて、少なくともASP2.0では

Server.Execute("hogehoge.aspx?UserCD='**'")

がきちんと通るし、hogehoge.aspxでも、UserCDを取得することができました。

まあ、ASP.NETは別物なんだから、できるようになったといえばそれでオシマイなんですがねw

Visual Studio 2008で既存のWebサイトで作成したアセンブリファイルを他サイトで利用する場合

Mr.T — Fri, 24 Oct 2008 18:22:00 GMT

Mr.Tです、こんにちは。

Visual Studio 2008ですが、おそらく2005でも同じじゃないかと思います。

ASP.NET Webサイトを構築する際、当初、VWD（Visual Web Developer）を利用していたため、

ソリューションファイルは作成できるものの、プロジェクトファイルが作成されません。

もちろん、Webサイトの発行ができるので、アセンブリファイルは当然ながら作成することができます。

発行したフォルダ→BinフォルダにApp_Code.dllというファイルがあるはず。

まずは、これを参照の追加で、追加します。

独自クラスや、カスタムコントロールはすべてここに集約されていますので、これだけで、独自に利用している名前空間を

指定できるのは、当然ですね。

この状態で、別ASP.NETアプリケーションから、上記アセンブリファイルを指定しようとする場合、<%@ Register %>ディレクティブを利用

して、aspxファイルで、独自のサーバーコントロールを利用するには、

<%@ Register　Assembly="App_Code" Namespace="MyNameSpace.MyProject" TagPrefix="Original" %>

という形にすれば、

<original:TagName>という形で利用できるようになるはずです。

Webサイトを指定してアプリケーションを作成した場合は、どうしてプロジェクトファイルができないのか不明ですが、

何かの足しになれば。

CustomValidatorを使って複合サーバコントロールに検証用のイベントを追加する

Mr.T — Wed, 05 Mar 2008 14:37:00 GMT

Mr.Tです、こんにちは。

ネタ元：http://www.ailight.jp/blog/kazuk/archive/2008/02/22/14491.aspx

ValidatorをASPXファイルに書いていると、やたらと行数を稼いでしまって、なんだか見難いようにも

おもってました。

今回は、今のプロジェクトで利用しているカスタムのコントロールに検証機能を追加するようにしてみたものです。

#コントロールは、プロジェクトで使用する製品CDのようなコード群をTextBox形式で扱うためのコントロールです。

入力値は必ずチェックをするものなので、基本チェックは何をしなくてもValidして欲しい、

更に、必要であれば個別にValidate処理を実装できるようにする必要がありました。

    Protected Overrides Sub CreateChildControls()
        nameTextBox = New TextBox
        nameTextBox.ID = NameTextBoxID
        nameTextBox.Width = Me.NameWidth
        nameValidator = New CustomValidator
        With nameValidator
            .ID = NameValidatorID
            .ValidationGroup = _validateGroupName
            .Text = "*"
        End With
        AddHandler nameValidator.ServerValidate, AddressOf OnServerValid
        Controls.Clear()
        Controls.Add(nameTextBox)
        Controls.Add(nameValidator)
    End Sub

    Private _targetServerValidateEventArgs As ServerValidateEventArgs
    Public Sub NameBoxValidate()
        Me.EnsureChildControls()
        _targetServerValidateEventArgs = New ServerValidateEventArgs(nameTextBox.Text, False)　...(*1)
        Me.OnTextServerValidate(Me, _targetServerValidateEventArgs)
        nameValidator.IsValid = _targetServerValidateEventArgs.IsValid
    End Sub

'サーバ上での基本Valid処理
    Private Sub OnServerValid(ByVal source As Object, ByVal events As ServerValidateEventArgs)
        If ************ Then
            events.IsValid = False
            nameValidator.ErrorMessage = Resources.****
        Else
            events.IsValid = True
            nameValidator.ErrorMessage = String.Empty
        End If
    End Sub

    Private Shared ReadOnly EventTextServerValidateKey As Object = New Object

    Public Custom Event TextServerValidate As ServerValidateEventHandler
        AddHandler(ByVal value As ServerValidateEventHandler)
            Events.AddHandler(EventTextServerValidateKey, value)
        End AddHandler

        RemoveHandler(ByVal value As ServerValidateEventHandler)
            Events.RemoveHandler(EventTextServerValidateKey, value)
        End RemoveHandler

        RaiseEvent(ByVal sender As Object, ByVal e As ServerValidateEventArgs)
            CType(Events(EventTextServerValidateKey), ServerValidateEventHandler).Invoke(Me, e)
        End RaiseEvent
    End Event

    Protected Overridable Sub OnTextServerValidate(ByVal source As Object, ByVal e As ServerValidateEventArgs)
        Dim validateHandler As ServerValidateEventHandler = CType(Events(EventTextServerValidateKey), ServerValidateEventHandler)

        EnsureChildControls()

        nameValidator.Validate()
        If EventTextServerValidateKey IsNot Nothing Then
            validateHandler(Me, e)
        End If
    End Sub

ASPX側では、

Protected Sub 個別Valid(byval sender as Object,byval e as ServerValidateEventArgs) handles CustomControl.TextServerValidate

ほにゃらら～

　ここで独自のチェックができるぞよ～

end Sub

そんなに難しいわけじゃないんですが、OnServerValidの呼び出しの際、ServerValidateEventArgsオブジェクトのパラメータを

どうするべと悩んだのはないしょです。

Clickイベントなどであれば、EventArgs.Emptyをパラメータとして渡せばよいわけですが、今回は、ServerValidateEventArgsなので、

ServerValidateEventArgs.Emptyを渡せません。

そんなら、インスタンスを渡せばええんかいな～と調べてみて、

http://msdn2.microsoft.com/en-gb/library/system.web.ui.webcontrols.servervalidateeventargs.servervalidateeventargs(ja-jp,VS.80).aspx

ここで、Valueと、IsValidを指定すればよいことがわかったので、そのまま(*1)実装。

で、渡したパラメータに対して、CustomValidatorコントロールのIsValidに結果をわたせばいいです。

検証コントロールなんかなくなってしまって、いい感じです。

SQLServer2005で、FOR XML を使うと「同じ XML タグに同じ属性を複数回生成することはできません」と怒られる。

Mr.T — Fri, 15 Feb 2008 18:35:00 GMT

Mr.Tです、こんにちは。

私自身、XMLってのはほとんど利用したことがない人で、使い道もよくわかっていないのですが、

TreeViewコントロールを使おうと決定してから、XMLでうんうん悩んでプログラムしています。

#System.Web.UI.WebControls.TreeViewクラスの方です。

TreeViewにはXMLDataSourceを利用して、データをバインドすることにしたので、

XMLDataSource.data = XMLデータ

TreeView.DataSourceID = XMLDataSource.ID

みたいな感じにしてやればあっさりバインドしてくれます。

さて、簡単にSQLServerでテーブルから、XMLとしてデータを取り出そうという場合、

select hoge1,hoge2,hoge3 from Table for XML AUTO

と書けば、すぐにXMLデータが取り出せます。

詳細にしたい場合は、Auto以外の指定もできるので、下のところを参考にしてみればよいと思います。

RAW モードの使用
 AUTO モードの使用
 EXPLICIT モードの使用

私がやっていたことは、

<工場からこうば>

　<工場 CD="1" Name="本社工場">

　　　<こうば CD="111"　Name=”Aこうば”＞

<製品 CD="111000" Name="製品A"/>

　　　</こうば＞

</工場>

</工場からこうば>

こんな感じのデータをイメージしてました。全てのノードで、属性が、CDとNameの二つがあります。

なので、これをとりだそうとして、Selectをかけようと思い、

select 工場.工場コード as [CD],工場.工場名 as [Name]

,こうば.こうばコード as [CD],こうば.こうば名 as [Name]

,製品.製品コード as [CD],製品.製品名 as [Name]

from T_工場工場

inner join T_工場リレーション

....

inner join T_こうばこうば

.....

inner join T_こうばリレーション

.....

#工場リレーションなどのテーブルは、工場とこうばの結びつきのデータが入ってます。

ところが、これをXML AUTOで出そうとすると怒られる。

列名 'CD' が繰り返されています。同じ XML タグに同じ属性を複数回生成することはできません。

メッセージから、すると、一つのノードに対して、CDを複数指定しているということだから、きちんとノードとして
それぞれのデータが認識されていないということになる。

ううん？なぜ、と思い、色々調べてみたのだけど、どうもいまいちわからない。

上記リンク先のAUTOモードの使用では、このように説明されている。

FROM 句の各テーブルは XML 要素として表され、そのうち少なくとも 1 列が SELECT 句のリストに含められます。FOR XML 句で省略可能な ELEMENTS オプションを指定すると、SELECT 句のリストに含められる列は属性またはサブ要素にマップされます。
生成される XML 内の要素が入れ子になった XML 階層は、SELECT 句で指定されている列で識別されるテーブルの順序に基づきます。そのため、SELECT 句で列名を指定する順序は重要です。先頭、つまり識別された左端のテーブルにより、生成される XML ドキュメント内の最上位要素が形成されます。SELECT ステートメント内の列で識別された左から 2 番目のテーブルにより、最上位要素内のサブ要素が形成されます。以降についても同様です。

テーブルが要素となり、指定している順番にサブ要素となる（つまり子になる）。同じテーブルから参照されるデータは、要素の属性となる

ということが書いてあります。

なのに、これじゃあ、指定ができない。

で、試行錯誤（Try&Error）してみたところ、こういうのはできるようです。

with 工場　as (

select ~ from T_工場

inner join T_工場リレーション

on ....

)

,with こうば as (

select ~ from T_こうば

　inner join T_こうば

on ....

)

select 工場.工場コード as [CD],工場.工場名 as [Name]

,こうば.こうばコード as [CD],こうば.こうば名 as [Name]

,製品.製品コード as [CD],製品.製品名 as [Name]

from 工場

inner join こうば

on 工場.こうばコード= こうば.こうばコード

....

CTE（共通テーブル式)を利用して、こういう形にするとできるんです。やっていることは一緒なんですけどね。

CTEを使った場合は、T_~リレーションというテーブルは最終XMLとして利用するSQL内には出てきませんので、

それが原因なのかなと思ってみたりもしたのですが、意味がよくわかりません。

今でも納得はできていないのです。

TreeNodeのLevelとDepth

Mr.T — Fri, 08 Feb 2008 11:51:00 GMT

Mr.Tです、こんにちは。

現在作成しているWebアプリケーションではTreeViewを頻繁に利用しているが、

そのときノードの深さを知りたいなと思い、たしかそんなプロパティがあったはず（でも、度忘れ）で、MSDNを調べてみた。

TreeViewのノードのプロパティ一覧から...あったよLevelプロパティ。

うん、感覚的にLevelってのはわかりやすかったので、素直に以下のページへ。

http://msdn2.microsoft.com/ja-jp/library/system.windows.forms.treenode.level(vs.80).aspx

Level プロパティの場合、ルートノードは入れ子の最初のレベルと見なされ、0 が返されます。

よしよしと、Treeview.Levelと打とうとしたら、アレレ...インテリセンスがきかへん。

あれ？と思って前のページを見直すと、System.Windows.Forms名前空間であるのに気がついた。

いや、そうじゃないんだ、System.Web.UI.WebControls 名前空間を調べないと。

で、同じように、検索してLevelプロパティを探す。

ない...

いや、おかしい、絶対あるはずと更に一覧を眺めると、Depthプロパティ...ナニ...？

http://msdn2.microsoft.com/ja-jp/library/system.web.ui.webcontrols.treenode.depth(VS.80).aspx

Depth プロパティを使用して、ノードの深さを確認します。深さは、ノードとルートノードの間の階層構造のレベル数を表します。たとえば、ルートノードの深さは 0 です。ルートノードの子ノードの深さは 1 です。以下同様です。

統一してないのね、こういうの。

ええ、開発チームが違うんでしょ。わかってますよ。

感覚的には、Levelがわかりやすいと思ったけど、Depthの方が日本語に近いのかな（深さとレベル）

でも、これって「ふいんき（変換できない）」 VS 「雰囲気」な的違いじゃね？と思ったりするのは、私だけでしょうか。

#いや違う。違うはずだ。違う...よね？

StateServerについてのメモ

Mr.T(mrt@wankuma.com) — Wed, 31 Oct 2007 12:06:00 GMT

Mr.Tです、こんにちは。

実は、こっそり、インスパイア。

http://d.hatena.ne.jp/NAL-6295/20071030/p1

StateServerは、ASP.NETを利用する上でSession情報を保持する際に、ASP.NET State Serviceというものを
利用します。

[サーバ側設定]

IISをインストールしていないとサービス自体が、出てこないので注意すること。

まずは、これを読むこと。けんけんふくよー。
http://msdn2.microsoft.com/ja-jp/library/ms178586(VS.80).aspx
サービスを起動させる。
サービス名は「ASP.NET State Service」
初期状態で起動は、手動であるため、「手動」→「自動」に挙げておくこと。
Firewallの設定を行う。
基本は、tcp 42424を使うので、それを通過するように指定。
このままクライアント側からのアクセスを受け付けると、実は次のようなエラーになる。

セッション状態要求をセッション状態サーバーに対して作成できませんでした。ASP.NET 状態サービスが開始されていて、クライアントとサーバーのポートが同じであることを確認してください。サーバーがリモートコンピュータ上にある場合、HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\aspnet_state\Parameters\AllowRemoteConnection の値を調べて、このコンピュータがリモート要求を受け付けることを確認してください。サーバーがローカルコンピュータ上にあり、上記のレジストリ値が存在していないか 0 に設定されている場合、状態サーバー接続文字列ではサーバー名に 'localhost' または '127.0.0.1' を指定しなければなりません。

なので、指定している通り、
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\aspnet_state\Parameters\AllowRemoteConnection
を調べて、なければつくる。値を0→1に変更

[クライアント側設定]

VS2005やWVDなら、既定のWebConfig内容では、sessionStateに関する表記がない。自前で、<sessionState>タグを書くこと。
表記の、大文字小文字には、注意すること、でないと、次のようなエラーになる。

説明: この要求を処理するために必要な構成ファイルの処理中にエラーが発生しました。以下のエラーの詳細を確認し、構成ファイルに変更を加えてください。
パーサーエラーメッセージ: 認識されない属性 'Mode' です。この属性は、大文字小文字を区別します。

この時点で最低限な設定は、
<sessionState mode="StateServer"
        stateConnectionString="tcpip=****:42424"
              cookieless="false"
              timeout="20"/>

くらいで接続できる。

あとは、特に設定なしでSession変数を利用することになる。

もし、SateServerを複数台にしてみたい場合は、こちらを参考に。→

State Serverはシングルポイントじゃないよ

関連リンク：ASP.NETでInProcを使ってはいけない

DataBinding.Evalを使わない（続き）

Mr.T(mrt@wankuma.com) — Sun, 16 Sep 2007 16:43:00 GMT

Mr.Tです、こんにちは。

http://blogs.wankuma.com/mrt/archive/2007/09/13/96121.aspx#FeedBackの続きになりますかね。

そもそも、Evalを使わないとなると明示的にCastすることになります。Castはいいんですが、

こんな使い方になりますね。（C#ですけど）えらく面倒というか、やはりもっと明示的に、直感的に指定したいです。

たとえば、表示したいViewは、こんなのとします。

工場コード	工場名
10	工場A
20	工場B
30	工場C

単なるマスタですが、そもそもこんな感じで表示するケースが基本じゃないかと思います。

で、これを表示するためのソースです。

（データソースコントロール）

Namespace MRT.OriginalControls

    '製造原価関連データベースへのアクセス用データソース基底クラス
    '    データソースクラス
    <AspNetHostingPermission(SecurityAction.LinkDemand, _
    level:=AspNetHostingPermissionLevel.Minimal), _
    AspNetHostingPermission(SecurityAction.InheritanceDemand, _
    level:=AspNetHostingPermissionLevel.Minimal), _
    ToolboxData("<{0}:OriginalDataSource runat=""Server""/>"), _
    Description("カスタムデータソース")> _
    Public Class OriginalSource
        Inherits DataSourceControl

' Implements IDataSourceOtherControlParameter

Private Const DefaultViewName As String = "defaultview"

        '唯一のView名を返す
        Protected Overrides Function GetViewNames() As System.Collections.ICollection
            Dim viewNames() As String = New String() {DefaultViewName}
            Return CType(viewNames, ICollection)
        End Function

        '既定のViewを返す
        Private _defaultView As OriginalDataSorceView
        Private ReadOnly Property DefaultView() As OriginalDataSorceView
            Get
                If (_defaultView Is Nothing) Then
                    _defaultView = New OriginalDataSorceView(Me, DefaultViewName)
                End If
                Return _defaultView
            End Get
        End Property

        Protected Overrides Function GetView(ByVal viewName As String) As System.Web.UI.DataSourceView
            If (viewName = String.Empty) Or _
                (viewName.ToLower = DefaultViewName.ToLower) Then

                Return DefaultView
            End If
            Throw New ArgumentOutOfRangeException(viewName)
        End Function
    End Class

    '規定のDataSourceView
    Public Class OriginalDataSorceView
        Inherits DataSourceView
        '       Implements IDataSourceOtherControlParameter

        Private _owner As OriginalSource
        Public Sub New(ByVal owner As OriginalSource, ByVal name As String)
            MyBase.New(owner, name)
            _owner = owner
        End Sub 'New

'ここでSelectしまっせ。
Protected Overrides Function ExecuteSelect(ByVal arguments As System.Web.UI.DataSourceSelectArguments) As System.Collections.IEnumerable

            Dim connectionString As String = "Data Source=****"
            Dim targetStoredProcedure As String = "dbo.GetFactoryTable"
            Dim targetDataReader As SqlDataReader
            Dim targetView As Queue(Of FactoryView) = New Queue(Of FactoryView)

Using targetSQLConnection As SqlConnection = New SqlConnection(connectionString)
Using targetSQLCommand As SqlCommand = New SqlCommand(targetStoredProcedure, targetSQLConnection)

'処理はパラメータ追加してのち、ストアドで実行
targetSQLCommand.Connection.Open()

targetSQLCommand.CommandType = CommandType.StoredProcedure
targetDataReader = targetSQLCommand.ExecuteReader(CommandBehavior.CloseConnection)

                    Dim fieldsCount As Integer = targetDataReader.FieldCount
                    While targetDataReader.Read()
                        Dim newView As FactoryView = New FactoryView
                        newView.FactoryCD = targetDataReader.GetValue(0).ToString
                        newView.FactoryName = targetDataReader.GetValue(1).ToString
                        targetView.Enqueue(newView)
                    End While

                    Return targetView
                End Using
            End Using

End Function
End Class

'アクセスされるView
Public Class FactoryView

        Private _factoryCD As String
        Public Property FactoryCD() As String
            Get
                Return _factoryCD
            End Get
            Set(ByVal value As String)
                _factoryCD = value
            End Set
        End Property

        Private _factoryName As String
        Public Property FactoryName() As String
            Get
                Return _factoryName
            End Get
            Set(ByVal value As String)
                _factoryName = value
            End Set
        End Property
    End Class

End Namespace

（表示コントロール）

Namespace MRT.OriginalControls

    'リスト表示するためのカスタムコントロール
    <AspNetHostingPermission(System.Security.Permissions.SecurityAction.Demand, _
    level:=AspNetHostingPermissionLevel.Minimal), _
    AspNetHostingPermission(System.Security.Permissions.SecurityAction.InheritanceDemand, _
    level:=AspNetHostingPermissionLevel.Minimal), _
    ToolboxData("<{0}:OriginalList runat=""Server""></{0}:OriginalList>"), _
    Description("リスト表示用カスタム"), _
    ParseChildren(True)> _
    Public Class OriginalList
        Inherits CompositeDataBoundControl

Private targetItemTemplate As ITemplate

        'コンテナ設定箇所
        <PersistenceMode(PersistenceMode.InnerProperty), _
        TemplateContainer(GetType(MasterContainer))> _
        Public Overridable Property ItemTemplate() As ITemplate
            Get
                Return targetItemTemplate
            End Get
            Set(ByVal value As ITemplate)
                targetItemTemplate = value
            End Set
        End Property

        'コントロール作成部分
        Protected Overrides Function CreateChildControls(ByVal dataSource As IEnumerable, _
                 ByVal dataBinding As Boolean) As Integer
            Dim loopCount As Integer = 0
            Dim targetEnumerator As IEnumerator = dataSource.GetEnumerator
            Dim listItemView As MasterContainer

Controls.Clear()
While targetEnumerator.MoveNext()

                listItemView = New MasterContainer(CType(targetEnumerator.Current, FactoryView))
                'テンプレートへの格納
                '上記のITemplateは、テンプレート適用のためのプロパティ
                targetItemTemplate.InstantiateIn(listItemView)
                If (dataBinding = True) Then
                    'バインドしないものはデータバインド処理にならない
                    listItemView.DataBind()
                End If

                Controls.Add(listItemView)
                loopCount += 1
            End While

            Return loopCount
        End Function
    End Class

    'コンテナ
    Public Class MasterContainer
        Inherits Control
        Implements INamingContainer '一意の名前をつけるために必要

        Public Sub New(ByVal targetView As FactoryView)
            FactoryItem = targetView
        End Sub

        Private _factoryItem As FactoryView
        Public Property FactoryItem() As FactoryView
            Get
                Return _factoryItem
            End Get
            Set(ByVal value As FactoryView)
                _factoryItem = value
            End Set
        End Property
    End Class
End Namespace

（ASPXファイル）

<%@ Page Language="VB" AutoEventWireup="false" CodeFile="Default.aspx.vb" Inherits="_Default" %>
<%@ Register TagPrefix="MyControl" Namespace="MRT.OriginalControls"%>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" >
<head runat="server">
    <title>無題のページ</title>
</head>
<body>
    <form id="form1" runat="server">
    <MyControl:OriginalSource runat="server" ID="OriginalDataSource1" />
    <table border ="1">
    <MyControl:OriginalList runat="server" ID="list1" DataSourceID="OriginalDataSource1">
    <ItemTemplate>
        <tr><td><%# container.FactoryItem.FactoryCD%></td><td><%# container.FactoryItem.FactoryName%></td></tr>
    </ItemTemplate>
    </MyControl:OriginalList>
    </table>
    </form>
</body>
</html>

とりあえず、ひとつのViewだけが対象になってるので、ソレ（ここではFactoryView)しか出てきません。
それに、取得条件も変更できるようにはなっていませんが...

container.FactoryItem.FactoryCD

こうやって、かけるようになりました。ありがとう>菊池さん

さて、菊池さんのBlogではExecuteSelectの部分がのってません。当たり前ですが、ここは何を扱うかで中身が
違うからなんですね。

キモは、IEnumerable で返さないといけないってことです。
今回はQueueを使いましたが、順序とか特にきにしないなら、Listでも返せます。

DataBinding.Evalを使わない

Mr.T(mrt@wankuma.com) — Thu, 13 Sep 2007 21:00:00 GMT

Mr.Tです、こんにちは。

ASP.NETでデータバインドの際に使われるDataBinding.Evalって使ってます？
私は、今のメインで行っているプログラム(ASP.NET）では、このEvalはまったく使ってません。
というのも、

インテリセンス大好きだから

.(ドット)を打って一覧に出てこないのは悪です（適当）

Eval使わずにどうやってGridViewとかを使うんじゃ、となると、

菊池 Blog:なま暖かくて柔らかい、ちょっと触るとプルプル動く

http://www.ailight.jp/blog/kazuk/archive/2006/11/05/13271.aspx

#古いエントリへのトラックバックってなんか申し訳ないような気がするのは、私だけ？

で、のってたC#をVB.NETにしこしこ置き換えて、つくってるということをしてます。機会をみて
サンプルをのせようとおもいます。
#その際にはツッコミ、お願いします>皆様

HogeDataSourceにプロパティ作成して、どのデータを呼ぶかをEnum定義でそれをASPXで簡単設定
ただ、編集なんかはまだサポートしてない。単純に表示するだけのListBOXしかつくってねーんですが。

Evalつかわねー場合、コンテナに入れる独自のViewをつくんなくちゃいけないんですが、

Public Class HogeView
Private _hogeProperty as String

         Pubic Property HogeProperty () as String
           Get
                  return _hogeProperty
           End Get
         Set(ByVal Value As Integer)
                 _hogeProperty =value
          end Set
end Class

こうやったら、<%# Container.HogeView.HogeProperty%>でかける。このかけたときの快感はわすれられねーです。
まあ、ExecuteSelectで返すのが、IEnumerableなので、最初にここではまったんですがね。
ええ、だって見事にDataRowView派生をつくらなくてはいけない道にはまりましたから。orz

実は、HogeProperty をプロパティにしてるのはきちんと理由があって、Public HogeProperty as String
ってしちゃうとエラーになりまする。
#これも別エントリにしようかなぁ。

関係ないですが、この記事を読んで、しびれたんですね。ビリビリと。

プログラマという職業の人がいればきっとできるよ。

カッコエエ。「オレもプログラマになりたーい」と半分素人な私。

HTTPContext Is Nothing

Mr.T(mrt@wankuma.com) — Mon, 03 Sep 2007 15:21:00 GMT

Mr.Tです、こんにちは。

　いわゆる非同期で扱いたい場合の処理では、Threadを使いページのリロードを行いつつ結果をまたせる、という処理を行う。

　この手のものはよくあるのかもしれないのだが、そこで一つ重大な問題点がある。

　HttpContext.currentが取得できない！

　ちょうど、thread.start()のメソッドを実行したときから取得できなくなる。

　うーん、うーん、どーして？似たような事例がないかと思ったが、世界は広い。

　それが、コレ：http://www.velocityreviews.com/forums/t58163-httpcontext-is-nothing-in-new-thread-inside-a-control.html

　英語だが、そう難しい単語もないので、なんとか意味は取れたと思うが...

　原因わかってねーじゃん。パラメータとして渡せ、ってことしか書いてねえ。

　確かに、パラメータとして渡せばいけたんだけどさ...

　うーむ、うーむ...なんで？　え？もしかして、わかってないの、オレだけ？