VB

「VBプログラマが知るべき9のこと」が@ITに転載されました

まさる（高野将、TAKANO Sho） — Wed, 11 May 2011 22:11:00 GMT

.NET開発を始めるVB6プログラマーが知るべき9のこと－＠IT

@IT：Insider.NETの「.NET開発者中心」にて、今日から始まった企画の第1回目として、誠に恐縮ながら私の記事が選ばれました。

オリジナルから若干の校正、修正が加わり、少し読みやすくなっています。（デジタルアドバンテージ様に感謝！）

私の記事が掲載されたのは次の企画。

.NET開発者中心厳選ブログ記事－＠IT

世界中にあるブログ・コンテンツから優秀なブログ記事を編集部が厳選して転載。

これからどんな記事が紹介されていくのか楽しみですね！

VBプログラマが知るべき9のこと by @masaru_b_cl

まさる（高野将、TAKANO Sho） — Sat, 26 Feb 2011 12:39:00 GMT

なんとなく「はてな」の方に書きました。

VBプログラマが知るべき9のこと by @masaru_b_cl

間違い、認識違いなどあったら、躊躇なくツッコミお願いします<(_ _)>

XElementをXmlNodeに変換

まさる — Fri, 11 Dec 2009 22:11:00 GMT

ちょっと必要になったので。

＃コードはXMLリテラルでXElementが簡単に作れるVBで。

その１：XmlDocument.LoadXmlメソッドにXElementをToStringして食わせる

Dim xelm = _
  <parent>
    <child>
      ほげほげ
    </child>
  </parent>

Dim xmlDoc As New XmlDocument()
xmlDoc.LoadXml(xelm.ToString())

その２：XmlDocument.LoadメソッドにXElement.CreateReaderで作成したXmlReaderを食わせる

Dim xelm = _
  <parent>
    <child>
      ほげほげ
    </child>
  </parent>

Using reader As XmlReader = xelm.CreateReader()
  Dim xmlDoc As New XmlDocument()
  xmlDoc.Load(reader)
End Using

なんか他にいい方法があったら教えてください。

VWDでVBを選んだ場合、既定でOption StrictはOff

まさる — Wed, 21 Oct 2009 00:14:00 GMT

VWDを使ってWebサイトを作成してWeb.configを見てみると・・・

というわけで、Option Strictは既定でOffなのです。

ですので、もちろん分離コードでこんなこと書いてもビルドエラーにはなりません。

かといって、Web.configを直しても自動的にOption Strinct Onになってくれるわけではないようで、

Option Strict Onにしたかったら、分離コードで明示的に指定してやる必要があるようです。

だからVBは嫌いなんだorz

C#だったらこんなことはないのに・・・

[追記：2009/10/26]

このエントリは「ASP.NET Web サイト」の場合についてです。「ASP.NET Web アプリケーションプロジェクト」の場合、プロジェクトのプロパティからOption Strictの設定は可能です。

また、ダッチさんのコメントによると、「ASP.NET Web サイト」の場合も、web.configファイルをいじくることで、Option Strictを有効にできるようです。

FizzBuzz＞それLINQで＞それワンライナーで

まさる — Sat, 03 Oct 2009 08:15:00 GMT

なんか某社長の記事発端なのか、また流行ってるみたいなので。

＃「1から10までの総和」祭りもそれよね

C#

Enumerable.Range(1,100).Select(n=>n%15==0?"FizzBuzz":n%3==0?"Fizz":n%5==0?"Buzz":n.ToString()).ToList().ForEach(Console.WriteLine);

VB

Enumerable.Range(1,100).Select(Function(n)If(n Mod 15=0,"FizzBuzz",If(n Mod 3=0,"Fizz",If(n Mod 5=0,"Buzz",n.ToString())))).ToList().ForEach(AddressOf Console.WriteLine)

VBでProducer/Consumerパターン

まさる — Wed, 16 Sep 2009 22:31:00 GMT

ネタ元：生産者と消費者

＃勝手にportしちゃうぞ企画第２段ｗ

今回はMSDNライブラリ「方法 : producer スレッドと consumer スレッドを同期する (C# プログラミングガイド)」のコードをVBにportしました。

VBに変換する際気を付けるのは、以下のような点。

lockステートメントはSyncLock
配列の初期化方法が違う

コードは以下の通り。

Imports System.Threading

Public Class SyncEvents
	Private _newItemEvent As EventWaitHandle
	Public ReadOnly Property NewItemEvent() As EventWaitHandle
		Get
			Return _newItemEvent
		End Get
	End Property

	Private _exitThreadEvent As EventWaitHandle
	Public ReadOnly Property ExitThreadEvent() As EventWaitHandle
		Get
			Return _exitThreadEvent
		End Get
	End Property

	Private _eventArray As WaitHandle()
	Public ReadOnly Property EventArray() As WaitHandle()
		Get
			Return _eventArray
		End Get
	End Property

	Public Sub New()
		_newItemEvent = New AutoResetEvent(False)
		_exitThreadEvent = New ManualResetEvent(False)
		_eventArray = New WaitHandle() {_newItemEvent, _exitThreadEvent}
	End Sub
End Class

Public Class Producer
	Private _queue As Queue(Of Integer)
	Private _syncEvents As SyncEvents

	Public Sub New(ByVal q As Queue(Of Integer), ByVal e As SyncEvents)
		_queue = q
		_syncEvents = e
	End Sub

	Public Sub ThreadRun()
		Dim count As Integer = 0
		Dim r As New Random()
		While Not _syncEvents.ExitThreadEvent.WaitOne(0, False)
			SyncLock DirectCast(_queue, ICollection).SyncRoot
				While _queue.Count < 20
					_queue.Enqueue(r.Next(0, 100))
					_syncEvents.NewItemEvent.Set()
					count += 1
				End While
			End SyncLock
		End While
		Console.WriteLine("Producer thread: produced {0} items", count)
	End Sub
End Class

Public Class Consumer
	Private _queue As Queue(Of Integer)
	Private _syncEvents As SyncEvents

	Public Sub New(ByVal q As Queue(Of Integer), ByVal e As SyncEvents)
		_queue = q
		_syncEvents = e
	End Sub

	Public Sub ThreadRun()
		Dim count As Integer = 0
		While WaitHandle.WaitAny(_syncEvents.EventArray) <> 1
			SyncLock DirectCast(_queue, ICollection).SyncRoot
				Dim item As Integer = _queue.Dequeue()
				count += 1
			End SyncLock
		End While
		Console.WriteLine("Consumer thread: consumed {0} items", count)
	End Sub
End Class

Public Class Program
	Private Shared Sub ShowQueueContents(ByVal q As Queue(Of Integer))
		SyncLock DirectCast(q, ICollection).SyncRoot
			For Each item As Integer In q
				Console.Write("{0} ", item)
			Next
		End SyncLock
		Console.WriteLine()
	End Sub

	Public Shared Sub Main()
		Dim queue As New Queue(Of Integer)
		Dim syncEvent As New SyncEvents()

		Console.WriteLine("Configuring worker threads...")

		Dim producer As New Producer(queue, syncEvent)
		Dim cunsumer As New Consumer(queue, syncEvent)

		Dim producerThread As New Thread(AddressOf producer.ThreadRun)
		Dim consumerThread As New Thread(AddressOf cunsumer.ThreadRun)

		Console.WriteLine("Launching producer and consumer threads...")

		producerThread.Start()
		consumerThread.Start()

		For i As Integer = 0 To 3
			Thread.Sleep(2500)
			ShowQueueContents(queue)
		Next i

		Console.WriteLine("Signaling threadds to terminate...")

		syncEvent.ExitThreadEvent.Set()

		producerThread.Join()
		consumerThread.Join()
	End Sub
End Class

「オススメしないとはいうものの」をVBに直してみた

まさる — Tue, 01 Sep 2009 19:41:00 GMT

ネタ元：オススメしないとはいうものの

いや、ホントになんとなくですけどｗ

＃未コンパイル、未検証なので、色々間違ってるかも。

あげる側 Form1

Public Partial Class Form1

  Public Sub New()
    InitializeComponent()
    self_ = Me   ' ここでオノレをセット
  End Sub

  Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
    Dim form2 As New Form2()
    form2.Show()
  End Sub

  Private Shared self_ As Form1

  ' read-onlyならまぁ、実害もなかろうと。
  Public ReadOnly Property GlobalValue() As String
    Get
      Return self_.TextBox1.Text
    End Get
  End Property

End Class

もらう側 Form2

Public Partial Class Form2

  Public Sub New()
    InitializeComponent()
  End Sub

  Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
    TextBox1.Text = Form1.GlobalValue       ' ここでもらう。
  End Sub

End Class

VB10の複数行のラムダ式

まさる — Thu, 18 Jun 2009 06:11:00 GMT

ネタ元：青柳臣一ブログ（総合） [VB10] Visual Basic 2010 の新機能

うわ・・・

Visual Studio 2010 - Visual Basic : Lambda Expressions

Dim increment2 = Function(x)
                     Return x + 2
                 End Function

きもっ！

VB9のIf演算子の戻り値の型は第2、第3引数の型になる

まさる — Fri, 13 Mar 2009 23:36:00 GMT

VB9で追加されたIf演算子。今までのIIf関数ではショートサーキットしてくれなかったので、非常にありがたく使わせてもらっています。

このIf演算子の戻り値の型は、タイトル通り第2、第3引数の型から推論されて決定されるようです。

' String型
Dim value1 = If(True, Nothing, "hoge")
' Integer型
Dim value2 = If(True, Nothing, 0)
' Date型
Dim value3 = If(True, Nothing, DateTime.Today)

では、次のコードの結果はどうなるでしょうか？

' valueに格納される値は？
Dim value As Nullable(Of Date) = If(True, Nothing, DateTime.Today)

…

わかりましたか？

答えは、Date型の 0001/01/01 0:00:00 です。

なぜこのような動きになるのかは、以下のように考えられます。

If演算子の結果はNothing
しかし、第3引数はDate型なので、値をDate型で返そうとする
Date型の変数にNothingを代入した際、DateTime.MinValueが設定される
したがって、valueにはDateTime.MinValueが設定される

最初この動作を見た時は意味がわからなくて焦りました(^^;

なお、値をNullable(Of Date)で返すには、キャストを使って次のようにしなければなりません。

Dim value5 As Nullable(Of Date) = _
 DirectCast(If(True, Nothing, DirectCast(DateTime.Today, Object)) _
 　, Nullable(Of Date))

ちなみに、C#で条件演算子を使った場合、

DateTime? value4 = true ? null : DateTime.Today;

というコードはコンパイルエラーになります。

やはりキャストを使って、

DateTime? value5 = (DateTime?) (true ? null : (object)DateTime.Today);

とする必要があります。

＃個人的にはコンパイルエラーにしてくれるC#の方が好きです。

[追記：2009/03/15]

よねけんさんが指摘してくださいました。NothingをNullable(Of Date)にキャストするだけでよかったようです。

また、このコードの場合は、暗黙的型定義もされるようなので、結論としては以下のようにすればもっとすっきりするようです。

Dim value6 = If(True, DirectCast(Nothing, Date?), DateTime.Today)

ちなみにC#の場合は次の通り。

var value6 = true ? (DateTime?)null : DateTime.Today;

あともう一つ、VB9ではNullable型の定義に「(型名)?」のように、「?」を添付する形式が使えるようになっていたことを知りませんでした。

小さいけれど、これもうれしい変更の一つですね。

DataTableのある列を集計する

まさる — Fri, 13 Mar 2009 22:49:00 GMT

従来、DataTableのある列（例えば数量、金額など）を集計する際は、foreachを用いて以下のようにしていたかと思います。

C#

var sumQty = 0m;
foreach (dr in dt)
{
	sumQty += dr.Qty;
}

VB

Dim sumQty = 0D
For Each dr In dt
	sumQty += dr.Qty
Next

これが、.NET Framework 3.5 以降では、LINQを用いて以下のように書けます。

C#

var sumQty = dt.Select(dr => dr.Qty).Sum();

VB

Dim sumQty = dt.Select(Function(dr) dr.Qty).Sum()

単純な集計とはいえ、foreachを書かなくていいのはわかりやすくていいですね。

なお、次のようにしてもできます。IEnumerable(T)のSumメソッドを使います。

C#

var sumQty = dt.Sum(dr => dr.Qty);

VB

Dim sumQty = dt.Sum(Function(dr) dr.Qty)

しかし、このやり方では、VBの方で「dr.」を入力した後、インテリセンスにQtyがてきません。

C#は問題なくインテリセンスが利くので、VBの今後の型推論機能に期待ですね。