[VB][C#] イベントアクセサ

kazuto — Wed, 25 Mar 2009 20:23:00 GMT

イベントにはイベントアクセサと言うものがありますが、VBでのイベントアクセサに少し違和感。
発端はVBでのイベントアクセサに指定するデリゲートは「戻り値の型を持つ事が出来ない」事からです。

VBではコードによるイベントのアタッチは下記の方法が一般的には使用されているように見えます。
(あくまでも自分の経験上です）

AddHandler Button1.Click, AddressOf Button1_Click

C#でのアタッチ方法はこのようにします。

Button1.Click += Button1_Click;

この二つを比較すると、自分は断然C#の方が「ButtonのClickイベントにイベントハンドラを登録して！」のように感じます。
VBでのイベントアタッチは「ButtonがClickされたら、イベントハンドラを呼んでね♪」って感じます。

どちらも角度を変えた言い方であってどちらも正解だと思うのですが、VBではキーワードを使用した定義が多い為か、「呼んでね♪」って印象が植えつく理由の一つとして「キーワードが多い」事かな？って感じてます。
イベントアクセサの実装をスタートとして、VBで実現不可の実装を「目的のみ達成するアプローチ」を試しにやってみます。

- VB -

Public Class Sample
    Private funcList As Func(Of Boolean) = Function() False

    Public Custom Event Func As Func(Of Boolean)
        AddHandler(ByVal value As Action(Of String))
            funcList = DirectCast([Delegate].Combine(funcList, value), Func(Of Boolean))
        End AddHandler
        RemoveHandler(ByVal value As Func(Of Boolean))
            funcList = DirectCast([Delegate].Remove(funcList, value), Func(Of Boolean))
        End RemoveHandler
        RaiseEvent()
            OnFunc()
        End RaiseEvent
    End Event

    Protected Overridable Sub OnFunc()
        For Each func As Func(Of Boolean) In funcList.GetInvocationList()
            If func IsNot Nothing Then
                Dim result As Boolean = func()
            End If
        Next
    End Sub
End Class

- C# -

public class Sample
{
    Func<bool> funcList = () => false;

    public event Func<bool> Func
    {
        add { funcList += value; }
        remove { funcList -= value; }
    }

    protected virtual void OnFunc()
    {
        foreach (Func<bool> func in funcList.GetInvocationList())
        {
            if (func != null)
            {
                bool result = func();
            }
        }
    }
}

上記実装ではVBではコンパイルエラーになります。これはVBでのイベントアクセサでは「イベントに戻り値の型があるデリゲートは指定出来ない」という仕様があるためです。
なのでこの問題を回避する為に、イベントアクセサを使用せずイベントアクセサメソッドを実装して回避します。

Public Class Sample
    Private funcList As Func(Of Boolean) = Function() False

    Public Sub AddFunc(ByVal value As Func(Of Boolean))
        funcList = DirectCast([Delegate].Combine(funcList, value), Func(Of Boolean))
    End Sub

    Public Sub RemoveFunc(ByVal value As Func(Of Boolean))
        funcList = DirectCast([Delegate].Remove(funcList, value), Func(Of Boolean))
    End Sub

    Protected Overridable Sub OnFunc()
        For Each func As Func(Of Boolean) In funcList.GetInvocationList()
            If func IsNot Nothing Then
                Dim result As Boolean = func()
            End If
        Next
    End Sub
End Class

もうこの時点で「Eventキーワード」を捨てる事になり、そのクラスを使用する側への提供アプローチを変える必要があります。
また外部よりイベントを発行を行わせない為にも、「funcList」変数は外部に公開出来ません。
イベントとして外部からはもう見えないので、イベントアクセサメソッドのみしか残らないので、使用する側からしたら「なんでAddFuncやRemoveFuncが必要なのよ！！！！」と言われちゃいます。

「いやいや・・・。イベントとして実装出来ないから、イベントハンドラをデリゲートリストに登録して頂きたく思っているのですが・・・」って言ってる間に
「イベントハンドラは登録するんじゃなく呼んでもらうんだよっっっ！！！！」

こんな展開になります。
VBでは「RaiseEventキーワード」があるので通常イベント発行はデリゲートを直接呼ぶ事はないですが、C#のようにデリゲートを呼んでイベント発行を行う事も出来るわけで・・。

まず、戻り値のあるイベント実装ってVBでは見た事ない（出来ない）ので、こんな実装アプローチはしないと思いますが、以前MSDNマガジン2008年9月号で掲載されているWPF におけるルーティングイベントとルーティングコマンドについて内のカスタムコマンドのサンプル実装をVBに落として試していた時に違和感を感じる事になったのがきっかけです。
そもそも言語が違うしこのような物はいっぱいあるんだと思いますが、VB側目線（自分はほぼVB開発が主なので）で見た場合「キーワードを使用して植えついてしまう印象と、目的は達成出来てもキーワードを捨てる事によるギャップ」が凄く感じる件でした。

結論は「きちんと学習しましょう」になるんだと思いますが、ちょっとした言語の違いを感じる事だったので (^^;
このような言語の違いって見つけて調べるのって何気に楽しいですね。

ってかC#の開発をやりたいな・・・。

[Windowsアプリケーション][VisualBasic] カスタムコントロールは難しい

kazuto — Tue, 13 Jan 2009 16:28:00 GMT

カスタムコントロールの実装は難しい・・。

今回、某掲示板の質問で「TextBoxを継承したカスタムコントロールのスマートタグにある"MultiLine"を非表示にしたい。」と言うものがあり、解いてみようと試みたが完全に行き詰まりました。

まず、System.Windows.Forms.Design.ControlDesignerクラスの派生クラスを実装し、それをカスタムコントロールのDesignerAttributeに指定してみたがこれだと既存のControlDesignerを上書いてしまい継承元のControlDesignerの機能を捨てる事になってしまう。
具体的には既存のControlDesignerの機能を使用しつつも、「既存スマートタグ内のDesignerActionListを無効、または非表示にする」事が出来ないかやってみたが、この手の情報が余りにも無さすぎです・・。

とりあえずこんな感じの実装をしてみました。

Imports System
Imports System.ComponentModel
Imports System.ComponentModel.Design

Public Class CustomTextBoxActionList
    Inherits DesignerActionList

    Public Sub New(ByVal component As IComponent)
        MyBase.New(component)
    End Sub

    Public Overrides Function GetSortedActionItems() As System.ComponentModel.Design.DesignerActionItemCollection
        Dim items As New DesignerActionItemCollection()
        'とりあえずヘッダーアイテムのみ追加
        items.Add(New DesignerActionHeaderItem("Sample Header"))
        Return items
    End Function
End Class

このようにカスタムコントロールのスマートタグに追加するSystem.ComponentModel.Design.DesignActionListクラスの派生クラスを作り、確認用にヘッダーアイテムのみ返却。

次にカスタムコントロールクラスをこんな感じで。

Imports System
Imports System.ComponentModel
Imports System.ComponentModel.Design

Public Class CustomTextBox
    Inherits TextBox

    Private action As DesignerActionList

    Public Sub New()
        MyBase.New()
    End Sub

    Protected Overrides Sub OnHandleCreated(ByVal e As System.EventArgs)
        MyBase.OnHandleCreated(e)

        If Me.Site Is Nothing Then Return

        Dim designerActionService As DesignerActionService = TryCast(Me.GetService(GetType(DesignerActionService)), DesignerActionService)
        Dim designerHost As IDesignerHost = TryCast(Me.GetService(GetType(IDesignerHost)), IDesignerHost)

        If (designerActionService IsNot Nothing) AndAlso (designerHost IsNot Nothing) Then
            Dim lists As DesignerActionListCollection = designerActionService.GetComponentActions(Me)
            'ここが微妙・・・
            For Each list As DesignerActionList In lists
                If list.GetType().Name = "TextBoxActionList" Then
                    designerActionService.Remove(Me, list)
                End If
            Next

            If Me.action Is Nothing Then
                Me.action = New CustomTextBoxActionList(Me)
            End If

            If Not lists.Contains(action) Then
                designerActionService.Add(Me, Me.action)
            End If
        End If
    End Sub
End Class

詳細としては

OnHandleCreatedメソッド内でDesignerActionServiceを取得する。
取得したDesignerActionServiceのGetComponentActionsメソッドを使用して既存のスマートタグアイテムを取得する。
既存のスマートタグアイテム("MultiLine")を、DesignerActionServiceのRemoveメソッドを使用して削除する。(今回名前判断をしてますが、他に判定方法が解らなかった・・)
カスタムスマートタグアイテムをDesignerActionServiceのAddメソッドを使用して追加する。

このような実装ですが、今までカスタムスマートタグを追加するならDesignerActionServiceクラスを使用して追加すれば良いと思っていたので、削除も同様にDesignerActionServiceクラスを使用して削除すれば良いと思っていたら削除されないわけです。

カスタムスマートタグアイテムはきちんと追加されるのに既存スマートタグを削除する事が出来ません！！！（キッパリ
そもそも、ここらへんで良く使用するDesigner～ホニャララやIDesigner～ホニャララなどと言った物の分かりやすい情報が上手く見つけれない。

皆さんはどのようにここらへんの勉強をされてますか？
本当に難しいですね・・・orz