VB.NET

Bing Translator ツール翻訳API その2

Thu, 09 Jul 2009 23:58:00 GMT

　さくっと残りのメソッドも確認します。Microsoft Translator（サービスはBing Translatorで、技術的な名前としてはMicrosoft Translatorって感じかな）でサポートしている言語一覧を取得するにはGetLanguagesメソッドを使います。

Dim client = New ServiceReference1.LanguageServiceClient
For Each l In client.GetLanguages("取得した Application ID")
    Console.WriteLine(l)
Next

　これでjaやenといった文字列が取得できます。

　GetLanguagesの代わりに、GetLanguageNamesを使用すると指定した言語でサポートしている言語名が取得できます。

Dim client = New ServiceReference1.LanguageServiceClient
For Each l In client.GetLanguageNames("取得した Application ID", "ja")
    Console.WriteLine(l)
Next

　さて、肝心の翻訳はTranslateメソッドを使います。引数は、Application ID、翻訳するテキスト、元の言語を示す文字列（jaなど）、翻訳先の言語を示す文字列（enなど）です。

Dim client = New ServiceReference1.LanguageServiceClient
Console.WriteLine(client.Translate("取得した Application ID", "こんにちは世界", "ja", "en"))

　簡単ですねー。これを使えば、以前紹介した翻訳系のWindows Live Writerのプラグインも作れちゃいそうですね（紹介したプラグインはすぐに公開されなくなってしまった）。

Bing Translator ツール翻訳API

Wed, 08 Jul 2009 22:36:00 GMT

　Bing Translator ツールに開発者向けに翻訳用のSDKが公開されています。今日はこれを使ってみよう。Bing自体にも翻訳機能が付いたというニュースはあるのだけれど、全然機能が確認できないのよね。Webブラウザの言語を英語にしたり試みているのだけれど。それはさておき。

　翻訳用のAPIは、同様の機能がAjax、HTTP、SOAPインターフェースの3種類が提供されています。.NET Frameworkから触るにはSOAPが激簡単だよねってことでこれを見てみます。

　はじめにApplication IDという識別子を取得しておく必要があります。これはLive Search時代のLive Search APIのものと共用のようですね。Bing Developer Center から必要事項を入力してApplication IDを取得します。

　鯉のぼり…だと…？　Application IDは、40文字ぐらいの0～9・A～Fの文字列です。

　それではAPIを使ってみます。Visual Studioを起動して、ここではコンソールアプリケーションを選択しました。ソリューションエクスプローラからプロジェクトを右クリックして、サービス参照の追加を選択します。

　アドレス欄には「http://api.microsofttranslator.com/V1/Soap.svc」と入力しましょう。移動ボタンをクリックします。メソッドが4個用意されていることがわかります。OKボタンもクリックしましょう。

　コードを入力します。私ぐらいになるとフィーリングでわかります。嘘です。ですが、用意されているメソッドとその内容はとってもシンプル。Detectメソッドは入力テキストの言語を検出してくれるものです。

Sub Main()
    Dim client = New ServiceReference1.LanguageServiceClient
    Console.WriteLine(client.Detect("取得した Application ID", "こんにちは"))
    Console.ReadLine()
End Sub

　実行すると…、おお日本語(=ja)と判別されました。

　今日はこのへんでいいでしょう（早っ）。残りのメソッドの使い方も超簡単です。

Silverlight UpdateSourceTrigger

Wed, 18 Mar 2009 20:31:00 GMT

　SilverlightではUpdateSourceTriggerが使えない。でも使いたい。検索してみると、Forumにそれを実現するコードがあるので書いてみました。

Binding.UpdateSourceTrigger : The Official Microsoft Silverlight Site

　VB.NETに変換して……。

Public Class UpdateSourceTriggerHelper
    Public Shared ReadOnly UpdateSourceTriggerProperty As DependencyProperty = _
        DependencyProperty.RegisterAttached("UpdateSourceTrigger", GetType(Boolean), GetType(UpdateSourceTriggerHelper), New PropertyMetadata(AddressOf OnUpdateSourceTriggerChanged))

    Public Shared Function GetUpdateSourceTrigger(ByVal d As DependencyObject) As Boolean
        Return CBool(d.GetValue(UpdateSourceTriggerProperty))
    End Function

    Public Shared Sub SetUpdateSourceTrigger(ByVal d As DependencyObject, ByVal value As Boolean)
        d.SetValue(UpdateSourceTriggerProperty, value)
    End Sub

    Private Shared _textBox As TextBox

    Private Shared Sub OnUpdateSourceTriggerChanged(ByVal d As DependencyObject, ByVal e As DependencyPropertyChangedEventArgs)
        If Not TypeOf d Is TextBox Then
            Exit Sub
        End If
        _textBox = DirectCast(d, TextBox)
        If CBool(e.OldValue) Then
            RemoveHandler _textBox.TextChanged, AddressOf TextBox_TextChanged
        End If
        If CBool(e.NewValue) Then
            AddHandler _textBox.TextChanged, AddressOf TextBox_TextChanged
        End If
    End Sub

    Private Shared Sub TextBox_TextChanged(ByVal sender As Object, ByVal e As EventArgs)
        Dim c = FindFocusableControl(_textBox)
        If c IsNot Nothing Then
            c.Focus()
        End If
        _textBox.Focus()
    End Sub

    Private Shared Function FindFocusableControl(ByVal control As Control) As Control
        Dim ctl = VisualTreeHelper.GetParent(control)
        If TypeOf ctl Is Control Then
            Return DirectCast(ctl, Control)
        Else
            Dim childrenCount = VisualTreeHelper.GetChildrenCount(ctl)
            For i = 0 To childrenCount - 1
                Dim c = TryCast(VisualTreeHelper.GetChild(ctl, i), Control)
                If c IsNot Nothing AndAlso Not c Is control Then
                    Return c
                End If
            Next
        End If
        Return Nothing
    End Function
End Class

XAMLはこんな感じ。

<TextBox Text="{Binding Hoge, Mode=TwoWay}" 
	local:UpdateSourceTriggerHelper.UpdateSourceTrigger="True" />

　処理内容は、TextChangedイベントが発生したらまわりのコントロールを探して、一度フォーカスを別のコントロールに変えて、またTextBoxに戻すというもの。これでUpdateSourceTriggerみたいに振舞うようにするってことですね。

　実際にうごかしてみると、フォーカスが移動しているということは見た目状わかりませんが、だーーーーめがっさ英語圏的な実装じゃないかこれ。入力中にフォーカス移動させたら日本語打てないじゃん……。難しいなあ。

smtp.live.comでメール送信

Wed, 11 Mar 2009 01:01:00 GMT

　先日（といっても結構たちましたかね）に、Live HotmailでSMTP認証が使えるようになりました。Liveメールを使用している私には特に関係ない話しだったんですが（Live Hotmail=Webメール、Liveメール=メールクライアント）、プログラムからメール送信に使いたいと思って調べてみた。

　公式ヘルプを見たのだけど、わかりにくい！　ニュースとしてはSMTP認証が使える！　ってことが取り上げられていたと思うけどヘルプにはそんなこと書いてなくて、「Microsoft Outlook に電子メールアカウントを追加する」の「POP3 サーバーを使用して Microsoft Outlook に Windows Live Hotmail の電子メールアカウントを追加する」としてちらりとSMTPサーバーのアドレスが書いてあります。

　そんなわけでコードで書くと以下の通り。認証とSSL通信使用がポイントかな？　値を変えるだけでGMailもいけました。ポートは25番ですが、たいていのプロバイダでは使えないと思うので変更が必要です。

Public Shared Sub Send()

    Dim title = "件名"
    Dim body = "本文"
    Dim toAddress = "jz5あlive.jp".Replace("あ", "@") ' 宛先
    Dim fromAddress = "jz5あlive.jp".Replace("あ", "@") ' 差出人

    Dim smtpServer = "smtp.live.com" ' SMTPサーバー
    Dim port = 25 ' ポート番号

    Dim userName = "jz5あlive.jp".Replace("あ", "@") ' Live ID メールアドレス
    Dim password = "*****" ' Live ID パスワード

    Dim encoding = System.Text.Encoding.UTF8
    Dim message As New MailMessage()

    With message
        .SubjectEncoding = encoding
        .BodyEncoding = encoding
        .From = New MailAddress(fromAddress, "ＪＺ５", encoding)
        .To.Add(New MailAddress(toAddress, "ＪＺ５", encoding))
        .Subject = title
        .Body = body
    End With

    Dim client = New SmtpClient() With { _
            .Host = smtpServer, _
            .Port = port, _
            .Credentials = New NetworkCredential(userName, password), _
            .EnableSsl = True}

    client.Send(message) ' 送信
End Sub

Silverlight DataGrid マウスホイールでスクロール

Wed, 11 Mar 2009 00:26:00 GMT

　Silverlight 使い始めました。マウスホイールでスクロールできないなんて……。以下、ほとんど文章だけなんでわかりにくいと思いますが。

　DataGridをマウスホイール対応するには、以前kazukiさんが書かれていますね。[C#][Silverlight]DataGridのマウスホイールでのスクロールその２この方法は選択行を変える方法でしたが、もっと自然な動作させる実装が、Silverlight2.0 - DataGridをホイールマウススクロールに対応させる - PYRO :: Blog にありました。すっごいぬるぬる動くよ！

　後者は、LoadingRowとUnloadingRowイベントにより現在表示されている行の最大と最小のインデックス値を保持しておいて、スクロール時にインデックス±1の行へスクロールするという手法です。

　が、こっちもソートすると、うまく動いてくれませんでした。最初はソートされてもインデックス値が変わらないのかなと思ったのですが、きちんとインデックス値は変わっていました。ソート時に表示されている行だけLoadingRow、UnloadingRowイベントが発生しますが、昇順 or 降順に発生しないので最大と最小の行のインデックス値がおかしくなってしまうっぽい。

　そこで、LoadingRow、UnloadingRowイベントで現在表示されている行のインデックスすべてを保持するように変えてみました。

Private indexs As New List(Of Integer)

Private Shadows Sub OnLoadingRow(ByVal sender As Object, ByVal args As DataGridRowEventArgs)
    If Not indexs.Contains(args.Row.GetIndex) Then
        indexs.Add(args.Row.GetIndex)
    End If
End Sub

Private Shadows Sub OnUnloadingRow(ByVal sender As Object, ByVal args As DataGridRowEventArgs)
    If indexs.Contains(args.Row.GetIndex) Then
        indexs.Remove(args.Row.GetIndex)
    End If
End Sub

　ScrollIntoViewsメソッドで対象の行へスクロールするのだけど、ここで問題が。メソッドにはItemsSourcesにあるオブジェクトを指定するのだけど、IList型にキャストしてインデックス値から導き出すとItemsSource自体はソートされていないので、スクロールした位置にあるオブジェクトを指定できないのね（元のコードはListにキャストしてるけどおなじだよね？ Listってなに？）。

Dim s = DirectCast(ItemsSource, System.Collections.IList)
Dim i As Integer
If mousedelta < 0 Then
    i = indexs.Max + 1
ElseIf mousedelta > 0 Then
    i = indexs.Min - 1
End If

If i < 0 Then
    i = 0
ElseIf i > s.Count - 1 Then
    i = s.Count - 1
End If
Me.ScrollIntoView(s(i), Me.Columns(0))

　ItemsSourceに指定するコレクションとキャストする型を考えればなんとかなりそう！　ってことでたどり着いたのが、CollectionViewModel。よくは読んでいないのだけど、M-V-VMパターンについてのエントリを訳してみた3　原題"CollectionViewModel" から原文に行ってサンプルをダウンロードして該当クラスだけとりだして使ってみると一応動きました（ItemsSourceとキャストにはICollectionView、行数を取得するのにIList型にもキャストして使用）。

　ソートしてもきちんとマウスホイールでスクロールできるのだけど、ものすごいCollectionViewModel生成のところかな？　時間がかかる。150行ぐらいなのだけど、ブラウザが固まってしまう……。ううーむ？　←今ここ。

WPF Toolkit DataGrid DisplayIndex

Tue, 03 Mar 2009 00:00:00 GMT

　このところめがっさフィードを確認してないけど（Googleリーダーはずっと1000+だぜ！）、コードはいろいろ書いてます。この前からWPF ToolkitのDataGridをさわってるのだけど、いろいろむずかしいわぁ。やりたいことがなかなかできない。

　カラムの並び替えを記憶および再現する際にDisplayIndexが使えるってこの前書いたけど、設定順？によっては落ちてしまう場合があるようですね。当然、0～カラム数-1の範囲で設定している状態です。

'datagrid: Microsoft.Windows.Controls.DataGrid
datagrid.Columns(0).DisplayIndex = 2
datagrid.Columns(1).DisplayIndex = 1
datagrid.Columns(2).DisplayIndex = 0

　情報も見つからなくて正しい方法がわからないのだけど、とりあえず毎回DisplayIndexを設定するときにUpdateLayoutメソッドを呼ぶと正常に動作するようです。

datagrid.UpdateLayout

　スタイル設定の動作などとってもDataGridたいへんです……。まだ解決してない事項がいろいろと。

プロパティを検証するコード　＠MVVM

Wed, 25 Feb 2009 20:01:00 GMT

　今朝通勤途中、紙のMSDNマガジン（英語）を読んでいたのだけど（あまり読めないので（英語的な意味で）内容がどんなのあるか確認する程度）、WPF MVVMパターン良さそうですね → WPF のための MODEL-VIEW-VIEWMODEL (MVVM) デザインパターン　すでにkazukiさんがエントリされてました（流石）→ [WPF][C#]Model View ViewModelパターンでハローワールド

　パターンとは少し関係ないかもだけど、記事中のプロパティを検証するコードが良い感じですね。INotifyPropertyChangedインターフェースを使うと、プロパティ名を文字列で扱うのでスペルミスしてしまうことがあるんですよね。それの対策コード。

Public Event PropertyChanged(ByVal sender As Object, ByVal e As PropertyChangedEventArgs) Implements INotifyPropertyChanged.PropertyChanged

Public Sub OnPropertyChanged(ByVal propertyName As String)
    Me.VerifyPropertyName(propertyName)
    RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
End Sub

<Conditional("DEBUG"), DebuggerStepThrough()> _
Public Sub VerifyPropertyName(ByVal propertyName As String)
    If TypeDescriptor.GetProperties(Me)(propertyName) Is Nothing Then
        Dim msg As String = "Invalid property name: " & propertyName
        If Me.ThrowOnInvalidPropertyName Then
            Throw New Exception(msg)
        Else
            Debug.Fail(msg)
        End If
    End If
End Sub

Private privateThrowOnInvalidPropertyName As Boolean = True
Protected Overridable Property ThrowOnInvalidPropertyName() As Boolean
    Get
        Return privateThrowOnInvalidPropertyName
    End Get
    Set(ByVal value As Boolean)
        privateThrowOnInvalidPropertyName = value
    End Set
End Property

　詳しくは記事＆コードで（まだ読んでない）。VB.NETでもコードサンプルが提供されていることに少し感動したｗ

Code for "WPF Apps With the Model-View-ViewModel Design Pattern" - Release: Initial Release

WPF Toolkit DataGrid ContextMenuとクリック処理

Fri, 30 Jan 2009 02:03:00 GMT

　続 WPF Toolkit DataGrid。前回 WPF Toolkit ListViewとしてのDataGrid

　まぁ、普通 ListViewとして使う場合、右クリックメニューとダブルクリック処理はいるよねーってことで調べてみると、どっちもCodePlexのDiscussionsに似たようなことが書いてありました。

　クリックしたときの行を取得するにはListViewと同じような感じかな？　あまりスマートじゃない。

　ContextMenuは、DataGridのContextMenuに書いてしまうと、行の上でもスクロールバーの上でもメニューが出てしまうのでStyleを使って書けば良いみたい。

<Window.Resources>
    <ContextMenu x:Key="ColumnHeaderContextMenu">
        <MenuItem Header="Foo" />
    </ContextMenu>
    <ContextMenu x:Key="RowContextMenu">
        <MenuItem Header="Bar" />
    </ContextMenu>

    <Style x:Key="DefaultCellStyle" TargetType="{x:Type dg:DataGridCell}">
        <Setter Property="BorderThickness" Value="0" />
    </Style>
    <Style x:Key="DefaultColumnHeaderStyle" TargetType="{x:Type dg:DataGridColumnHeader}">
        <Setter Property="ContextMenu" Value="{StaticResource ColumnHeaderContextMenu}" />
    </Style>
    <Style x:Key="DefaultRowStyle" TargetType="{x:Type dg:DataGridRow}">
        <Setter Property="ContextMenu" Value="{StaticResource RowContextMenu}" />
    </Style>
</Window.Resources>
<Grid>
    <dg:DataGrid
        x:Name="DataGrid"
        AutoGenerateColumns="False"
        GridLinesVisibility="None"
        HeadersVisibility="Column"
        IsReadOnly="True"
        SelectionUnit="FullRow"
        CellStyle="{StaticResource DefaultCellStyle}"
        ItemsSource="{Binding Path=Persons}"
        ColumnHeaderStyle="{StaticResource DefaultColumnHeaderStyle}"
        RowStyle="{StaticResource DefaultRowStyle}"
        MouseDoubleClick="DataGird_MouseDoubleClick">
        <dg:DataGrid.Columns>
            <dg:DataGridTextColumn Header="名前" 
                                   Binding="{Binding Path=Name}"
                                   Visibility="Visible"/>
            <dg:DataGridTextColumn Header="年齢" 
                                   Binding="{Binding Path=Age}" />
        </dg:DataGrid.Columns>                                   
    </dg:DataGrid>
</Grid>

Private Sub DataGird_MouseDoubleClick(ByVal sender As System.Object, ByVal e As System.Windows.Input.MouseButtonEventArgs)
    Dim d = DirectCast(e.OriginalSource, DependencyObject)
    Do While d IsNot Nothing AndAlso _
        Not TypeOf d Is DataGridCell AndAlso _
        Not TypeOf d Is DataGridColumnHeader
        d = VisualTreeHelper.GetParent(d)
    Loop
    If d Is Nothing Then
        Exit Sub
    ElseIf TypeOf d Is DataGridColumnHeader Then
        ' DataGridColumnHeader !
    ElseIf TypeOf d Is DataGridCell Then
        ' DataGridCell !
    End If
End Sub

　DataGridのColumnHeaderStyleとRowStyleとMouseDoubleClickのところに注目です。列ヘッダの右クリックメニューで、チェックボックス付きのメニューを表示して、列の表示・非表示設定を行いたいけど、それはどうすれば良いのかな。

WPF Toolkit ListViewとしてのDataGrid

Fri, 30 Jan 2009 00:50:00 GMT

　最近、WPFのListViewをいじっているんですが、ソート機能は A Sortable GridView (I mean ListView) Control in WPF(翻訳中):.knowledge - frog.raindrop.jp を参考にそれなりのものができたのだけど、ヘッダをドラッグ＆ドロップで入れ替えた際にそれを保存してアプリを起動時に再現する方法が全然わからない。

　というわけで、Windows Presentation Foundation (WPF) - Release: WPF Toolkit - October 2008 Release のDataGridを試してみました。きっかけはtech days 2009を見て。あくまでListViewらしく見た目を変えます。

　こんな風にXAMLを書きます。選択範囲をRow単位にしてもどのセルを選択しているかわかってしまうのでセルのStyleを変えてます。

<Window.Resources>
    <Style x:Key="DefaultCellStyle" TargetType="{x:Type dg:DataGridCell}">
        <Setter Property="BorderThickness" Value="0" />
    </Style>
</Window.Resources>
<Grid>
    <dg:DataGrid
        x:Name="DataGrid"
        AutoGenerateColumns="False"
        GridLinesVisibility="None"
        HeadersVisibility="Column"
        IsReadOnly="True"
        SelectionUnit="FullRow"
        CellStyle="{StaticResource DefaultCellStyle}"
        ItemsSource="{Binding Path=Persons}">
        <dg:DataGrid.Columns>
            <dg:DataGridTextColumn Header="名前" 
                                   Binding="{Binding Path=Name}" />
            <dg:DataGridTextColumn Header="年齢" 
                                   Binding="{Binding Path=Age}" />
        </dg:DataGrid.Columns>                                   
    </dg:DataGrid>
</Grid>

　結果、こんな感じ。良いですねー。デフォルトでソート機能も付いてます。ソート機能をヘッダに持たせたくない場合は、DataGrid***ColumnのCanUserSortプロパティをFalseにします。すると、ヘッダがボタンのように押下できなくなります。すんばらしー。

　さて、DataGird***Columnには、DisplayIndexというプロパティを持っていて、XAMLで書いた順番とは別に、表示順が管理されています。これで指定した順番で列を表示できるし、取得も可能。これで解決です！

DataGrid.Columns(0).DisplayIndex = 1

FirePropertyChanged と Microsoft.Design

Fri, 30 Jan 2009 00:04:00 GMT

ネタ元： NotifyPropertyChangedBase

　私は中さんのコードを参考にしてWPFを始めたので、この FirePropertyChanged メソッドが私のコードの中にはでてきます。ただし、VB.NETのコードですが。あとベースクラスとしても作っていませんね。

　ほとんどの人が気にしていないことだろうけども、このFireなんちゃらというメソッドは、「適切な場合にはイベントを使用します」にひっかかるんですよねぇ。Fire、AddOn、RemoveOn、Raiseはイベントに使用されるってことなんだけど、動詞だしメソッドじゃないのと思うのですがどうなんでしょう。イベントは過去分詞のイメージがあるけど Clicked じゃなくて Click と書くよね。悩ましい。