LINQ　with VB.NET

LINQ は面白い(って、わたし、この子リンキューって呼んじゃうのよね、ついｗ）

片桐　継（Tugu Katagiri） — Mon, 26 May 2008 00:49:00 GMT

たとえば、今動いているサービスをみてみたいなぁ、なんて作ってみた

Imports System.ServiceProcess

Module Module1
    Sub Main()
        Console.WriteLine("今動いているサービス名：")
        Dim Services = From service In ServiceController.GetServices() _
           Where service.Status = ServiceControllerStatus.Running _
           Order By service.ServiceName _
           Select service
        For Each Running In Services
            Console.WriteLine(Running.DisplayName)
        Next
    End Sub
End Module

すぐできた。LINQだとこんだけ。

これを知ってれば、特定のサービス動いてる？なんてチェックも一瞬だよね。

んで、もいっこ♪

Imports System.IO

Module Module1

    Sub Main()
        Console.WriteLine("今日作ったファイル")
        Dim Files = From file In Directory.GetFiles("c:\wankuma") _
           Where System.IO.File.GetCreationTime(file).ToString("yyyyMMdd")  _
                 = Date.Today.ToString("yyyyMMdd") _
           Order By (file) _
           Select file
        For Each Todays In Files
            Console.WriteLine(Todays)
        Next
    End Sub

End Module

これは、今日作ったファイルを探し出すクエリ。んでもって

こんなカンジ。

私はLINQってSQLで使うより、こっちで使うほうがはるかに多いような気がする。特定の集合から条件で何かを取り出す、って技術はありそうでなかった気がするの。

やっぱ、LINQって好き～（はぁと）

LINQ with VisualBasic.NET ～ペンギンを数えよう～

片桐　継（Tugu Katagiri） — Tue, 01 Jan 2008 22:14:00 GMT

この前は「ペンギンを探した」んですが

http://blogs.wankuma.com/esten/archive/2007/12/31/115566.aspx

今度は数えてみようという企画（笑）元のペンギンデータは一緒です。

msg = ""
For Each PenPen In From Pen In Penguins Group Penguins By Key = Pen.Item("Nestle") Into Count()
  msg += PenPen.Key & ":" & PenPen.Count & Chr(13)
Next
MsgBox(msg, , "営巣場所ごとのペンギン種類数")

今度はNestle別にGroupByしてCountを取りました。ポイントは、Group句の書き方がちょっとSQLと違うところ。慣れているとつい、GroupBy（KEY列）と書きたくなるけど、LINQではそうでなくて、Group　グループ名（任意）　By　KEY名（任意）　＝　グループ列句　の形式を取るところです。このKEY句はWhere句で使用することができるので、

msg = ""
For Each PenPen In From Pen In Penguins Group Penguins By Key = Pen.Item("Nestle") Into Count() _
                   Where Key = "岩場"
  msg += PenPen.Key & ":" & PenPen.Count & Chr(13)
Next
MsgBox(msg, , "岩場に営巣するペンギン種類数")

とか、

msg = ""
For Each PenPen In From Pen In Penguins Group Penguins By Key = Pen.Item("Nestle") Into Count() _
                   Where Count = 1
  msg += PenPen.Key & ":" & PenPen.Count & Chr(13)
Next
MsgBox(msg, , "営巣するペンギンが一種類")

とか言った条件設定に使うことができます。SQLのHAVING句に近い感覚です。SQLを使いこなしている人にはちょっと癖が強いかもですけれど、基本は同じ。しっかりつかめれば大丈夫大丈夫（笑）

というわけで、今年もよろしくお願いします

LINQ with VisualBasic.NET ～ペンギンをさがそう～

片桐　継（Tugu Katagiri） — Mon, 31 Dec 2007 11:56:00 GMT

というわけで覚書

まずは、ネタ元のペンギンテーブルを作成

Private Sub SetPenguins()

    Dim PenguinName() = {"フンボルトペンギン", "コビトペンギン", "イワトビペンギン", "コウテイペンギン"}
    Dim PenguinSize() = {60, 38, 61, 120}
    Dim PenguinLiving() = {"南アメリカ", "オーストラリア", "フォークランド諸島", "南極"}
    Dim PenguinNestle() = {"岩場", "巣穴", "岩場", "氷上"}

    Penguins = New DataTable
    Penguins.Columns.Add("Name", GetType(String))
    Penguins.Columns.Add("Size", GetType(Integer))
    Penguins.Columns.Add("Living", GetType(String))
    Penguins.Columns.Add("Nestle", GetType(String))

    Dim Penguin As DataRow
    For i = LBound(PenguinName) To UBound(PenguinName)

      Penguin = Penguins.NewRow()

      Penguin.Item("Name") = PenguinName(i)
      Penguin.Item("Size") = PenguinSize(i)
      Penguin.Item("Living") = PenguinLiving(i)
      Penguin.Item("Nestle") = PenguinNestle(i)

      Penguins.Rows.Add(Penguin)

    Next

  End Sub

あんまりここは代わり映えなく（笑）←おいこら

というわけで、このDataTableから色んなペンギンを探し出します

Dim msg = ""
SetPenguins()

msg = ""
Dim AllPenguin = From Pen In Penguins
For Each PenPen In AllPenguin
  msg += Join(PenPen.ItemArray, ":") & Chr(13)
Next
MsgBox(msg, , "全部のペンギン")

msg = ""
Dim MinPentuin = From Pen In Penguins Order By Pen.Item("Size") Take 1
For Each PenPen In MinPentuin
  msg = PenPen.Item("Name").ToString
Next
MsgBox(msg, , "最小のペンギン")

msg = ""
Dim MaxPentuin = From Pen In Penguins Order By Pen.Item("Size") Descending Take 1
For Each PenPen In MaxPentuin
  msg = PenPen.Item("Name").ToString
Next
MsgBox(msg, , "最大のペンギン")

msg = ""
Dim RockPenguin = From Pen In Penguins Where Pen.Item("Nestle").ToString = "岩場"
For Each PenPen In RockPenguin
  msg += PenPen.Item("Name").ToString & Chr(13)
Next
MsgBox(msg, , "岩場に営巣するペンギン")

で動かすと

こんな感じで出てきます。DataTableからデータをLINQした場合、取得するデータ型はDataRowCollectionとなります。Dimの後ろには変数を指定しているだけなので、VB.NET側で「じゃ、DataRowCollectionでよろしく」というわけですね

DataTableにあったSelectメソッドよりも柔軟な条件設定ができるのが大きい利点だと思うですよ

LINQ with VB.NET

LINQ は面白い(って、わたし、この子リンキューって呼んじゃうのよね、ついｗ）

LINQ with VisualBasic.NET ～ペンギンを数えよう～

LINQ with VisualBasic.NET ～ペンギンをさがそう～

LINQ　with VB.NET