発見した事

やまたのおろちが酒を飲む～片桐的VB.NETスレッドプログラミング～その３

片桐　継（Tugu Katagiri） — Sat, 27 Dec 2008 21:27:00 GMT

やまたのおろちが酒飲んでます。あいかわらずの飲兵衛です。

その１

http://blogs.wankuma.com/esten/archive/2008/12/03/162607.aspx

ここでは、ただ首一本がガブガブ飲むだけだったんだけど、それじゃ他の首が飲ませろとうるさいので、全部の首がせーのっ！で飲めるようにして

その２

http://blogs.wankuma.com/esten/archive/2008/12/09/163043.aspx

となったわけだけれども、コメントでツッコミがあったように、これだけでは全く持って、ダメダメプログラミングなわけですｗ。はい、わざとです。

では、どうしようか？　リファクタする？

でもその前に、まだやっておかなくちゃいけないことがあるんだわ。

やまたのおろちが飲みたい酒ツボが１つだったときにどうなるかって話。

Imports System
Imports System.Threading

Module OrochMTA

    Delegate Sub DrinkingSAKE()

    '酒ツボは一つ
    Private sakeTubo As Integer

    '酒ツボの残り
    Private sakeNokori As Integer

    <MTAThread()> _
  Public Sub Main()

    '酒ツボに酒を準備
    sakeTubo = 50000
    sakeNokori = sakeTubo

    '本体で首が別々に酒飲みするのを身構える

        Dim ts As New ThreadStart(AddressOf OrochiDrinking)

        Dim workerThread As New Thread(ts)

        workerThread.SetApartmentState(ApartmentState.MTA)

        workerThread.Start()

        workerThread.Join()

        Stop

  End Sub

    Private Sub OrochiDrinking()

        'まずは首を八本で飲んでみる
        Dim headCount As Integer = 8

        '酔っ払い待ち行列を首の数だけ準備
        Dim yoppa(headCount - 1) As WaitHandle

        For i As Integer = 1 To headCount

            '飲んだ首から酔っ払いへと
            yoppa(i - 1) = HeadDrinking(i).AsyncWaitHandle

        Next

        '全部の首が酔っ払いになるまで待機
        WaitHandle.WaitAll(yoppa)

    End Sub

    Private Function HeadDrinking(ByVal headNo As Integer) As IAsyncResult

        '指定した番号の首に酒を飲ませる
        Dim myHead As New OrochiHead(headNo)

        Dim gubi As New DrinkingSAKE(AddressOf myHead.Drink)

        '酒飲み開始とともに、酔っ払い待ち行列へ戻す
        Return gubi.BeginInvoke(Nothing, Nothing)

    End Function

    'おろちの首をクラス化
Private Class OrochiHead

    Private meNumber As Integer

    '何番目の首なのかを保存
    Public Sub New(ByVal headNo As Integer)

        meNumber = headNo

    End Sub

    '酒を飲むメソッド
    Public Sub Drink()

        Dim sakeZuki As New Thread( _
          New ThreadStart(AddressOf DrinkSAKE)) ' 

        sakeZuki.Start()
        sakeZuki.Join()

          Console.WriteLine("ぷはーっ！ {0}番目の首、飲み終わり！", meNumber)

    End Sub


  ' 酒のみスレッド
  Private Sub DrinkSAKE()

        Dim totalDrunk As Integer = 0
        Dim nowDrink As Integer

        Dim oneDrink As New Random
        Dim oneBreath As New Random

        '酒ツボの中の酒を飲み干す
        While (sakeNokori > 0)

            '一回飲むたびに息継ぎ
            Thread.Sleep(oneBreath.Next(30, 60))

            '一回ぐび
            nowDrink = oneDrink.Next(1, 100)

            '全部でどれくらい飲んだ？
            sakeNokori -= nowDrink

            Console.WriteLine("{0}番目の首が {1} リットル ぐびっ : 残り {2} リットル", meNumber, nowDrink, sakeNokori)


        End While

  End Sub

End Class

End Module

ぱっと見、これだけに見えるよね？

でも、これが落とし穴。

CPUの数が多い時、スレッドはどのCPUで管理されるかはOS次第。でもそのバラバラに動いているスレッドの処理が一箇所のアドレスにある値を読み出して書き出すわけだから、「今ある酒の量が本当に正しい」かどうか判らなくなる。これが小さなスレッドと一瞬で終わるプログラムなら気がつかないかもしれない。でも、沢山のCPU、スレッドで動いたときこの落とし穴ははっきりと結果にでてくるんだよね。

つまり、一つの酒ツボから複数の首が酒を飲むわけだけど、実際に、首の動きを制御しているのは、CPU。だから、CPUが複数あると、本当の意味で「同時に」首が酒を飲むことができるわけで、そうなると、酒ツボから飲んだ→残りこんだけ、という動きも本当の意味で「同時に」起きちゃうことになるの。そうなっちゃうと、今の酒の残り、は本当に正しい！ということがこのままだといえなくなっちゃうんだ。たとえば残り１００リットルから、ある首Aが２０リットル飲んで、ある首Bが１０リットル飲んだ。この時、本当だったら残りは７０リットルのはずなんだけど、２個のCPUがあるときに、Aの「100-20」の計算を１CPU、Bの「100-10」の計算を１CPUがそれぞれに同時にしちゃったら結果は「80」もしくは「90」として格納、これ、プログラム的には正しい動作なんだもの。見えないだけで、実はやまたのおろちの首はおもいっきり絡まってて、絡まったなりに酒を飲んだツモリになってたりしてるってことだよね。

厄介なのは、これ、必ず再現できると限らないんだ。

VisualStudioのデバッガをつかってブレークポイントを仕掛けて止めただけでも、マルチスレッドプログラミングは直列の処理に最適化されてしまうので、ステップするとうまくいっちゃったりとかする。「なんで？何が悪いの？」がさっぱり判らなくなっちゃう。

おそろしいよね、それって。

だから、スレッド間でやり取りする値、読み出したり書き出したり更新したりする時には、必ずスレッド間で同期を取れるように作ってあげないといけない。

マルチスレッドが難しいのはこの考え方があるからで、実はこれを回避するための処理クラスやステートメントが、ちゃんと用意されてたりするのね。

それが、InerLockedクラス、そして、SyncLockステートメントブロック

じゃ、こいつらを使って、やまたのおろちに行儀良くお酒を飲んでもらおうと思う。ついでに、リファクタってやつもやってみるってことで、それは次回ねｗ

実はまだ出てない新キャラがいるんだ、スサノオってのがｗｗｗ

やまたのおろちが酒を飲む～片桐的VB.NETスレッドプログラミング～その２

片桐　継（Tugu Katagiri） — Tue, 09 Dec 2008 10:23:00 GMT

やまたのおろちはお酒大好き。とりあえず前回は代表の首一本だけが酒ツボからグビグビいっちゃう想定でシングルスレッドのお話をしてたりなんかしたのね。

http://blogs.wankuma.com/esten/archive/2008/12/03/162607.aspx

でも、これだと他の酒のみ待ち首はきっとウルサイ。先に飲ませろ、俺に飲ませろ、まぁ黙れやこの飲兵衛よっぱらい爬虫類もどきドモがっ！といいたくなるような状況にきっとなっちゃう。

そこで、全部の首に、いっせーーーーの！で飲ませようというのが今回のお話、マルチスレッドね。

実は前回で、一つの首が酒を飲むのにデリゲートしてシングルスレッドで飲ませるところまではできた。つまり簡単に考えれば、シングルになっているところをマルチにするだけで、事は解決できるはず。

Imports System.Threading

Module OrochMTA

    Delegate Sub DrinkingSAKE()

    <MTAThread()> _
  Public Sub Main()

    '本体で首が別々に酒飲みするのを身構える

        Dim ts As New ThreadStart(AddressOf OrochiDrinking)

        Dim workerThread As New Thread(ts)

        workerThread.SetApartmentState(ApartmentState.MTA)

        workerThread.Start()

        workerThread.Join()

        Stop

  End Sub

    Private Sub OrochiDrinking()

        'まずは首を八本で飲んでみる
        Dim headCount As Integer = 8

        '酔っ払い待ち行列を首の数だけ準備
        Dim yoppa(headCount - 1) As WaitHandle

        For i As Integer = 1 To headCount

            '飲んだ首から酔っ払いへと
            yoppa(i - 1) = HeadDrinking(i).AsyncWaitHandle

        Next

        '全部の首が酔っ払いになるまで待機
        WaitHandle.WaitAll(yoppa)

    End Sub

    Private Function HeadDrinking(ByVal headNo As Integer) As IAsyncResult

        '指定した番号の首に酒を飲ませる
        Dim myHead As New OrochiHead(headNo)

        Dim gubi As New DrinkingSAKE(AddressOf myHead.Drink)

        '酒飲み開始とともに、酔っ払い待ち行列へ戻す
        Return gubi.BeginInvoke(Nothing, Nothing)

    End Function

    'おろちの首をクラス化
Private Class OrochiHead

    Private meNumber As Integer

    '何番目の首なのかを保存
    Public Sub New(ByVal headNo As Integer)

        meNumber = headNo

    End Sub

    '酒を飲むメソッド
    Public Sub Drink()

        Dim sakeZuki As New Thread( _
          New ThreadStart(AddressOf DrinkSAKE)) ' 

        sakeZuki.Start()
        sakeZuki.Join()

          Console.WriteLine("ぷはーっ！ {0}番目の首、飲み終わり！", meNumber)

    End Sub


  ' 酒のみスレッド
  Private Sub DrinkSAKE()

        '酒ツボの中の酒の量
        Dim totalSAKE As Integer = 1000

        Dim totalDrunk As Integer = 0
        Dim nowDrink As Integer

        Dim oneDrink As New Random
        Dim oneBreath As New Random

        '酒ツボの中の酒を飲み干す
        While (totalDrunk <= totalSAKE)

            '一回飲むたびに息継ぎ
            Thread.Sleep(oneBreath.Next(30, 60))

            '一回ぐび
            nowDrink = oneDrink.Next(1, 100)
            Console.WriteLine("{0}番目の首が {1} リットル ぐびっ", meNumber, nowDrink)

            '全部でどれくらい飲んだ？
            totalDrunk += nowDrink

        End While

  End Sub

End Class

End Module

変わった部分、あんまり無い（笑）。でも動かしてみると判るけど、全部の首が並列でぐびぐび酒飲んじゃう。

ポイントは、

７行目：<MTAThread()>
16行目：workerThread.SetApartmentState(ApartmentState.MTA)

これによって、「これから動かすスレッドは並列で動かすつもりなんでよろしく！」と準備して、

54行目：Return gubi.BeginInvoke(Nothing, Nothing)

で実際に、スレッドが「非同期で」起動、でもって、一つ一つのスレッドの背番号（IAsyncResultクラスのWaitHandle）をうけとって

42行目：WaitHandle.WaitAll(yoppa)

で全部の背番号にぶら下がったスレッドが終了するまで処理を待機する、ってところ。

なんだ、簡単じゃぁん！なんて思うでしょ？実際、簡単に見えてくるもの。でもこれがでっかいでっかい落とし穴。動くけど、このソースだけじゃまだまだダメだったりなんかする。過信するなよ、.NetFrameworkプログラミング（笑）

実は村で用意したのは馬鹿でかい酒ツボ一個。だから、首一つにつき酒ツボ一つじゃなくて、全部の首で一つの酒ツボから酒を飲むことになっちゃった！

って、この酒ツボが一個になった時に起きる時、マルチスレッドプログラミングで落っこちる地獄への入り口で、これがまた、ふっかーーい話だったりするの。覚悟せよ、次回（笑）

やまたのおろちが酒をのむ～片桐的VB.NETスレッドプログラミング～その１

片桐　継（Tugu Katagiri） — Wed, 03 Dec 2008 22:56:00 GMT

やまたのおろちって本体一つに八つの首があるんだって。３だとキングギドラで、４がヒュドラで、16だとミズノエリュウ、だったと思うの。で、このたくさんの首の一つ一つがドラゴンの顔になってて、口があって……。まぁ、ようするに、そんな彼らに酒を飲んでもらおうというコンセプトで、スレッドプログラミングの話をしてみようと思うんだ。

まずはシングルスレッドのお話。

まずはシンプルに、ふつーのシングルスレッド。代表の一本の首だけが飲ンベって想定で。流れとしては一本の首がごきゅごきゅと酒ツボを飲み干すっと。

Imports System.Threading

Module OrochSTA

  Public Sub Main()

    Dim hontai As New Thread( _
      New ThreadStart(AddressOf DrinkSAKE)) ' 

    hontai.Start()
    hontai.Join()

      Console.WriteLine("ぷはーっ！")

        Stop
  End Sub

  ' 酒のみスレッド
  Private Sub DrinkSAKE()

        '酒ツボの中の酒の量
        Dim totalSAKE As Integer = 1000

        Dim totalDrunk As Integer = 0
        Dim nowDrink As Integer

        Dim oneDrink As New Random
        Dim oneBreath As New Random

        '酒ツボの中の酒を飲み干す
        While (totalDrunk <= totalSAKE)

            '一回飲むたびに息継ぎ
            Thread.Sleep(oneBreath.Next(30, 60))

            '一回ぐび
            nowDrink = oneDrink.Next(1, 100)
            Console.WriteLine("{0} リットル ぐびっ", nowDrink)

            '全部でどれくらい飲んだ？
            totalDrunk += nowDrink

        End While

  End Sub

End Module

この場合、酒飲みはまだ一個の首でやってる。酒ツボも一つだけだから、さくーっとのんで終わり。で、つぎに、このおろちの首をクラス化して、その一本の首に酒を飲ませてみる。これが大事な前フリｗ。あとで首がたくさんになるからね。

Imports System.Threading

Module OrochSTA

  Public Sub Main()

    Dim myHead As New OrochiHead

        myHead.Drink()

        Stop
  End Sub

    'おろちの首をクラス化
Private Class OrochiHead

    '酒を飲むメソッド
    Public Sub Drink()

        Dim sakeZuki As New Thread( _
          New ThreadStart(AddressOf DrinkSAKE)) ' 

        sakeZuki.Start()
        sakeZuki.Join()

          Console.WriteLine("ぷはーっ！")

    End Sub


  ' 酒のみスレッド
  Private Sub DrinkSAKE()

        '酒ツボの中の酒の量
        Dim totalSAKE As Integer = 1000

        Dim totalDrunk As Integer = 0
        Dim nowDrink As Integer

        Dim oneDrink As New Random
        Dim oneBreath As New Random

        '酒ツボの中の酒を飲み干す
        While (totalDrunk <= totalSAKE)

            '一回飲むたびに息継ぎ
            Thread.Sleep(oneBreath.Next(30, 60))

            '一回ぐび
            nowDrink = oneDrink.Next(1, 100)
            Console.WriteLine("{0} リットル ぐびっ", nowDrink)

            '全部でどれくらい飲んだ？
            totalDrunk += nowDrink

        End While

  End Sub

End Class

End Module

で、首をクラス化することで、首が酒を飲む、というメソッドがラッピング。こうすると首一本のやるべきことが明確になる。そこで、飲ンベ首をデリゲートに登録して、さらに別スレッドで飲ませるように書き換えてみる。

Imports System
Imports System.Threading

Module OrochSTA

    Delegate Sub DrinkingSAKE()

  Public Sub Main()

    '本体で首が別々に酒飲みするのを身構える

        Dim ts As New ThreadStart(AddressOf OrochiDrinking)

        Dim workerThread As New Thread(ts)

        workerThread.SetApartmentState(ApartmentState.STA)

        workerThread.Start()

        workerThread.Join()

        Stop

  End Sub

    Private Sub OrochiDrinking()

        'まずは首を八本で飲んでみる
        Dim headCount As Integer = 8

        '全部の首が酒を飲み干す
        For i As Integer = 1 To headCount

            HeadDrinking(i)

        Next

    End Sub

    Private Sub HeadDrinking(ByVal headNo As Integer)

        '指定した番号の首に酒を飲ませる
        Dim myHead As New OrochiHead(headNo)

        Dim gubi As New DrinkingSAKE(AddressOf myHead.Drink)

        '酒飲み開始とともに、酔っ払い待ち行列へ戻す
        gubi.Invoke()

    End Sub

    'おろちの首をクラス化
Private Class OrochiHead

    Private meNumber As Integer

    '何番目の首なのかを保存
    Public Sub New(ByVal headNo As Integer)

        meNumber = headNo

    End Sub

    '酒を飲むメソッド
    Public Sub Drink()

        Dim sakeZuki As New Thread( _
          New ThreadStart(AddressOf DrinkSAKE)) ' 

        sakeZuki.Start()
        sakeZuki.Join()

          Console.WriteLine("ぷはーっ！ {0}番目の首、飲み終わり！", meNumber)

    End Sub


  ' 酒のみスレッド
  Private Sub DrinkSAKE()

        '酒ツボの中の酒の量
        Dim totalSAKE As Integer = 1000

        Dim totalDrunk As Integer = 0
        Dim nowDrink As Integer

        Dim oneDrink As New Random
        Dim oneBreath As New Random

        '酒ツボの中の酒を飲み干す
        While (totalDrunk <= totalSAKE)

            '一回飲むたびに息継ぎ
            Thread.Sleep(oneBreath.Next(30, 60))

            '一回ぐび
            nowDrink = oneDrink.Next(1, 100)
            Console.WriteLine("{0}番目の首が {1} リットル ぐびっ", meNumber, nowDrink)

            '全部でどれくらい飲んだ？
            totalDrunk += nowDrink

        End While

  End Sub

End Class

End Module

さて、こんなカンジで、首の一本一本が順番に酒を飲んで、順番に飲み終わり、をシングルスレッドで動いてるってことに置き換えてもこれだけの方法があったりする。でもね、飲ンベ首が増えたら、待たせるとウルサイから皆せーの！で飲んじゃいなYO！ってことで並列化させようと思うんだ。これがマルチスレッドでの動き。それはまた次にね

Hyper-Vってここがすごい！

片桐　継（Tugu Katagiri） — Tue, 23 Sep 2008 03:32:00 GMT

Hyper-Vで仮想マシンを再構築→OSインストール完了→VisualStudio2008インストール中

に悲劇は起きた

ホストマシン、WindowsServer2008が更新プログラムアップデートの関係でいきなりの再起動！！！

ここまでインストールできたのに（号泣）

しばし呆然としつつ、再起動したホストマシンから再度、ゲストマシンを見てみると……

VisualStudio2008のインストール、順調に続行中でした

つまり、ゲスト仮想マシンが稼動中に、ホスト側でOS停止が起きた場合でも、その停止直前の状態からゲスト仮想マシンは稼動継続できちゃうってことだね

さりげないけど、これってすごい！
この時間から再インストールなんて、それ何て拷問？だもんねぇ

ありがとうございましたです

片桐　継（Tugu Katagiri） — Sun, 21 Sep 2008 02:09:00 GMT

５月にディレクターをやった際、実はアンケートでこっぴどく叩かれて、正直それ以来凹んでました。

ダウナーな状態から色々と持病を悪化させてしまって、心身ともに相当なレベルにまでボロボロになってしまって、一時期、本気で、「私もうだめかもしんない」とまで思ってしまいました。

本職？をお休みして、完全に１プログラマとしての自分に徹して、初心に返って、苦手分野のスレッド処理やデザインパターンなんかも勉強して、没頭することをしてみて、すこしだけ、顔が上を向くようになったのが今年の夏です。

修羅場突入でTECH-edは行けず、今年の浴衣も着れず、フラストレーションためてるのに体力がもっとついていかなくて、「あー、年とったな、老いたな」なんて思って。

で、今日、がんばってみました。

初めて会う方と話ができて、知り合うことができて、懐かしい？人たちと話ができて、やっぱ相変わらずのダメ人間的よーわからんキャラな片桐の自分が自然と戻ってきたみたいです。

でも、乾杯って言いにくくない？　うち、なんか、言われへんかったわぁ……ごめんなさい　orz

勉強会という機会があること、色々な分野の人と色んな話ができること、これがどんなに凄い自身の宝物になるのか、力になるのか、まざまざと知った一日でした。

ありがとうございましたです、本当に。

よろしければまた、色々とお手伝いさせてください。

VB4どっぷり人間が頑張ってみたVB.Net

片桐　継（Tugu Katagiri） — Thu, 19 Jun 2008 12:53:00 GMT

こんなコンソールアプリを作ってみた。VisualStudio2005ね。

まー、何のことはない、びっくり箱っぽいものなのだけれど。VB4脳がこれをどう作ったかというとだ、

Module Module1

    '箱本体クラス
    Private Class SurpriseBox
        '箱の中身列挙
        Private Enum InnerObj
            None = 0
            Pegion = 1
            Cock = 2
            Duck = 3
        End Enum
        '箱の中身用メンバ変数
        Private _innerAnimal As InnerObj
        Private _innerVoices() As String = {"しーん", "ででっぽー", "くわーーかっかっか", "あふ○ーーくっ"}
        Private _innerAnswer() As String = {"からっぽ", "はと", "おんどり", "あふだっく"}

        '何が入っていたかプロパティ
        Public ReadOnly Property InnerAnswer() As String
            Get
                Return _innerAnswer(_innerAnimal)
            End Get
        End Property

        '箱に何かをいれる操作
        Public Sub SetSomething()

            _innerAnimal = CType(CInt((Rnd() * 100) Mod _
                                    [Enum].GetNames(GetType(InnerObj)).Length), SurpriseBox.InnerObj)
            Console.WriteLine("ハコになんかはいったよ")

        End Sub

        '箱に触ったよイベント宣言
        Private Event SomethingHappen()

        '箱に触ったよイベントで動く処理
        Private Sub OnSomethingHappen() Handles Me.SomethingHappen

            Console.WriteLine(_innerVoices(_innerAnimal))

        End Sub

        '箱に触わる操作
        Public Sub TouchBox()
            Console.WriteLine("さわったね！！")
            RaiseEvent SomethingHappen()
        End Sub

    End Class

    '回数先生
    Private Class BoxTeacher

        '結局先生が何回触れるようにしてくれたのかを知らせるプロパティ
        Public ReadOnly Property Count() As Integer
            Get
                Return _myCount
            End Get
        End Property

        'メンバ変数
        Private _limitCount As Integer
        Private _myCount As Integer

        '引数なしコンストラクタは最大１０回としとく
        Public Sub New()
            _limitCount = 10
        End Sub

        '引数つきコンストラクタは最大回数指定
        Public Sub New(ByVal pLimit As Integer)
            _limitCount = pLimit
        End Sub

        '教えて！先生！
        Public Sub TeachPlease()
            TeacherTaking()
        End Sub

        '「教えて！」すると先生登場。さぁ俺の話を聞け！
        Private Sub TeacherTaking()
            Dim setCount As Integer = 0

            '一応、再登場の時と挨拶が変わるらしい
            If _myCount > 0 Then
                Console.WriteLine(String.Format(" またあえたね！回数先生だ！こんども{0}回までOKだっ！", _limitCount))
            Else
                Console.WriteLine(String.Format(" やぁ！回数先生だ！さわりたい回数をいれようね！{0}回までOKだっ！", _limitCount))
            End If

            '入力まち
            Dim setCountStr As String = Console.ReadLine

            'ちゃんと数字がきたかどうかチェック
            'TryParse を知った時は衝撃だった
            If Integer.TryParse(setCountStr, setCount) = False Then
                Console.WriteLine("　数字入れなきゃ動かないよ")
                Console.WriteLine(" 先生はざんねんだっ！")
                _myCount = 0
                Exit Sub
            End If

            '回数が範囲内なのかチェック
            'OrElse を知った時は衝撃だった
            If setCount < 1 OrElse setCount > _limitCount Then
                Console.WriteLine(String.Format("　回数は、１回から{0}回。お約束しようね！", _limitCount))
                Console.WriteLine(" 先生はざんねんだっ！")
                _myCount = 0
                Exit Sub
            End If

            'メンバ変数に保存しておく。プロパティに直接触らせない。
            'こういうやり方が隠蔽ってことらしい
            _myCount = setCount

            'さよなら回数先生
            Console.WriteLine(" よぅし！よくやった！じゃ、先生は帰るよ！またなっ！")
        End Sub

    End Class

    'メイン処理
    Sub Main()

        '変数初期化
        Dim wRepeter As String = "Y"
        Dim setCount As Integer = 0
        Dim touchCount As Integer = 0
        Dim setObj As Integer = Nothing
        Dim myBox As New SurpriseBox
        Dim myTeacher As New BoxTeacher

        'Whileもすごいねー。DoLoopしか知らなかったので衝撃。
        While (wRepeter.ToUpper = "Y")

            'カウントアップも＋＝で書けるのが衝撃
            touchCount += 1

            'このあたりの作り方ってANSI-Cっぽいなんて思う
            Console.Clear()
            Console.WriteLine(String.Format("ハコをさわろう！何がでるかな？  {0}回目！", touchCount))

            'さわる回数は先生におまかせ
            'つまり、メインでは回数のチェックとか入力まちとかしない。
            '似たようなサブルーチン処理はVB4でもしていたけど、
            'クラスという違う世界？で記載して、その中身完全隠蔽っぽいことするっていうのは
            '意外と衝撃だったりする
            myTeacher.TeachPlease()

            '先生から回数おしえてもらうだけ。この回数も中でどうやってできてきたのかなんて
            'メインは知らないでいい。うわー衝撃だｗ
            setCount = myTeacher.Count
            If setCount = 0 Then
                Console.WriteLine("またきてね！")
                Exit While
            End If

            Console.WriteLine(String.Format("{0}回ハコがさわれるよ！何がでるかな？", setCount))

            'ここには書いてないのだけれど、Continueがさりげに使えるのも衝撃ｗｗｗ
            'ここもmyBoxの中身の動きは気にしない。
            For i As Integer = 1 To setCount

                Console.WriteLine(String.Format("{0}回目", i))

                'どれかをハコにセットする準備
                myBox.SetSomething()

                'ハコをさわってみた
                'ここで自作イベントが発生ですよ、これってすごいですよ！
                myBox.TouchBox()

                Console.WriteLine(String.Format("箱の中は……{0}！", myBox.InnerAnswer))
            Next

            Console.WriteLine("もっかいやる？[Y]")
            wRepeter = Console.ReadLine()

        End While

        Console.WriteLine("お・し・ま・い♪")
        Console.Read()

    End Sub

End Module

って、こんな感じ。

AddressOfも出てこないし、コメントにあるとおり、衝撃だらけｗ

でも、これをリファレンスほとんど見ないで、インテリセンスに頼ってはいたけど、コード作ってテストできた自分をちょっとほめたい。.Netに出会って一年たって、なんかちょっと懐いてくれた様な感覚というか、そんな感じです。まーこれも、VB6をやっていればもうちょっと、衝撃度は低かったのかもしれないけど。

で、本題（おい）

        If aInt => bInt Then
            aInt = 0
        End If

ってのを書いたら

        If aInt >= bInt Then
            aInt = 0
        End If

って勝手に直してくれることに気づいた（笑）VisualStudio2005、貴方こまかいのね（笑）

こんなん出た～

片桐　継（Tugu Katagiri） — Tue, 17 Jun 2008 20:50:00 GMT

やままださんちでも話題になってた帰ってきたSandCastleにちょい絡み？

そういや、ウルトラマンジャックって後付の名前で、TV放送リアルタイムは名無しさんだったんだよなぁ。メビウスで「ジャック兄さん」と聞いたときには正直感慨深かった（違っ）

てなわけで、こんなん見つけました～

Sandcastle Assist
http://www.codeplex.com/SandAssist

超大雑把にいうと

Sandcastle を使いやすくするためのコンポーネントセット

つまり、SandCastle SDKと機能をクラスライブラリ化して使えるようにしたものっぽい。

一時期、CodePlexから行方不明になっていたSandCastleでしたが、こういうものを引っさげて戻ってきた模様ですｗ

ってことで。

コマンドラインが浪漫って人はSandCastle単体で、

http://www.microsoft.com/downloads/details.aspx?FamilyId=E82EA71D-DA89-42EE-A715-696E3A4873B2&displaylang=en

とりあえず、HelpFile作りたい、って人は　Help File Builder とか DocProject で、

http://www.codeplex.com/SHFB
http://www.codeplex.com/DocProject

どっちもこれをいれとくと幸せになれるらしいｗ
http://www.codeplex.com/SandcastleStyles
http://www.codeplex.com/sandextensions

HelpFile作るツールを自作したい、自分のプログラムに組み込みたいって人はAssistで

http://www.codeplex.com/SandAssist

うーん、しっかり住みわけって感じですね

しかしここまでバラバラだと、静的サイト、つかまとめサイトいるんじゃね？

PowerShellをIDEで書いてみる

片桐　継（Tugu Katagiri） — Fri, 23 May 2008 00:21:00 GMT

こんなツールがあるのを発見（＾－＾）

PowerShell GUI

http://powergui.org/index.jspa

つまりは、PowerShellスクリプトを画面でのんびり書いて、ステップ実行でデバッグしながら動作確認できるツール。

スニペットも使えるし、インテリセンスも使える、ブレークポイントもできる。

ま、百聞は一見にしかず、デモムービーを見てもいいし、

http://powergui.org/shares/powergui/sbin/docs/PowerGUI_Introduction/PowerGUI_Introduction.html

ダウンロードしてもいいし、

http://powergui.org/downloads.jspa

可愛い汽車の壁紙、いかぁっすか？＜おい

Hyper-V が　RC1　になってまふ

片桐　継（Tugu Katagiri） — Wed, 21 May 2008 23:58:00 GMT

ダウンロードは以下で

http://www.microsoft.com/downloads/details.aspx?displaylang=ja&FamilyID=7edaa89f-9f64-488d-93c0-858d2d8799df

といっても、日本語対応となるのはもうちょっと後？

今年の夏にむけて順調に？近づいてきてる感じです。それよか、LinuxIntegrationKitが早く正式公開しないかなー。試したくてウズウズなんですけど（笑）

Hyper-V 動いたよーっ！

片桐　継（Tugu Katagiri） — Fri, 09 May 2008 22:40:00 GMT

ってことで、

http://blogs.wankuma.com/esten/archive/2008/05/07/136735.aspx

のリベンジ。うん、Windows Server 2008 Enterprise x64bit版でできましたです。

というわけで、前回と同じ「サーバーの役割」画面だけれど、こんなに違います。真ん中あたりに「Hyper-V」がありますね。さっそくいってみよー！

Hyper-Vを選んで「次へ」を押していくと、どんどん設定ができます。簡単です。もう何も考えなくていいやってくらい、楽チンでウィザードを進めていけます。

そうそう、ネットワークは使いたいので、もちろん、バインドさせておきます。ありがたいことに、購入したマザボの搭載LANはそのまま使えるようです。

そして、実際のゲストOSの設定ですが、isoイメージファイルからもできるのが便利。いちいちDiskに焼かなきゃならんのかなぁなんて思っていたので助かりました。

Isoファイルを指定してセットアップ開始。なんだかとても新鮮ｗ

ってことで、Hyper-V、ええわー、これｗ

自作マシンでも、できたよってことで（笑）